'Sterownik R&G PLUS SRG-6000p wzor Olsztynski
'Autor: EuroPoland mhm mhm mhm who asked

'###########################
'Ustawienie na poczatku
'###########################
{macro:6000p_init}
	1 (S.L.wylaczony)
	"6kP\6000p_e.dds" (S.$.6000p_ekran)
	"Fahrzeugnr.:" (L.$.ident) $+ (S.$.6000p_Nrpojazdu) 	
	0 (S.L.uruchomiony)
	0 (S.L.BylOdjazd)
{end}

'###########################
'Aktywne caly czas
'###########################

{macro:6000p_frame}

1 (S.L.Refresh_Strings)

(L.S.Year) (S.L.year)
(L.S.DayOfYear) (S.L.dayofyear)
(L.S.Day) (S.L.day)

' 	YY = (rok-1) mod 100
(L.L.year) 1 - (S.L.YY)
(L.L.YY) 100 % (S.L.YY)

'	C = (rok-1) - YY
(L.L.year) (L.L.YY) 1 - - (S.L.C)

'	G = (YY + YY/4)
(L.L.YY) 4 / (S.L.G)
(L.L.G) (L.L.YY) + (S.L.G)

'	dt1 = (((((C / 100) mod 4) * 5) + G) mod 7)
(L.L.C) 100 / (S.L.dt1)
(L.L.dt1) 4 % (S.L.dt1)
(L.L.dt1) 5 * (S.L.dt1)
(L.L.dt1) (L.L.G) + (S.L.dt1)
(L.L.dt1) 7 % (S.L.dt1)

'	dt = dt1 + DayOfYear - 1) mod 7
(L.L.dt1) (L.L.dayofyear) + (S.L.dt)
(L.L.dt) 1 - (S.L.dt)
(L.L.dt) 7 % (S.L.dt)

(L.L.elec_busbar_main)
{if}
	(L.L.wylaczony) 1 =
	{if}
		(L.L.liczenie1) (L.S.Timegap) + (S.L.liczenie1)
		(L.L.liczenie1) 5 >=
		{if}
			0 (S.L.wylaczony)				
			1 (S.L.boot_mode)
			"6kP\6000p_e_boot1.dds" (S.$.6000p_ekran)
			0 (S.L.liczenie1)
			1 (S.L.uruchomiony)
			(T.L.6000p_piep)			
		{endif}
	{endif}
	(L.L.boot_mode) 1 =
	{if}
		(L.L.liczenie1) (L.S.Timegap) + (S.L.liczenie1)
		(L.L.liczenie1) 2 >=
		{if}
			2 (S.L.boot_mode)
			"6kP\6000p_e_boot2.dds" (S.$.6000p_ekran)			
			0 (S.L.liczenie1)
		{endif}
	{endif}
	(L.L.boot_mode) 2 =
	{if}
		(L.L.liczenie1) (L.S.Timegap) + (S.L.liczenie1)
		(L.L.liczenie1) 3 >=
		{if}
			3 (S.L.boot_mode)
			"6kP\6000p_e_boot3.dds" (S.$.6000p_ekran)			
			0 (S.L.liczenie1)
		{endif}
	{endif}
	(L.L.boot_mode) 3 =
	{if}
		(L.L.liczenie1) (L.S.Timegap) + (S.L.liczenie1)
		(L.L.liczenie1) 2.5 >=
		{if}
			4 (S.L.boot_mode)
			"6kP\6000p_e_boot4.dds" (S.$.6000p_ekran)			
			0 (S.L.liczenie1)
		{endif}
	{endif}
	(L.L.boot_mode) 4 =
	{if}
		(L.L.liczenie1) (L.S.Timegap) + (S.L.liczenie1)
		(L.L.liczenie1) 1 >=
		{if}
			5 (S.L.boot_mode)
			"6kP\6000p_e_boot5.dds" (S.$.6000p_ekran)			
			0 (S.L.liczenie1)
		{endif}
	{endif}
	(L.L.boot_mode) 5 =
	{if}
		(L.L.liczenie1) (L.S.Timegap) + (S.L.liczenie1)
		(L.L.liczenie1) 3 >=
		{if}
			0 (S.L.boot_mode)
			1 (S.L.6000p_loginID)
			"6kP\6000p_e_loginID.dds" (S.$.6000p_ekran)			
			0 (S.L.liczenie1)
		{endif}
	{endif}	
	
	(M.L.brygadowka)
	

	"" "" $+ (L.S.Time) 3600 / s0 trunc s1 " 2" $IntToStrEnh $+ ":" $+
	l0 l1 - 60 * s2 trunc s3 "02" $IntToStrEnh $+ ":" $+
	l2 l3 - 60 * trunc "02" $IntToStrEnh $+
	(S.$.6000p_Godzina)


	"" "" $+ (L.S.Day) "02" $IntToStrEnh $+ "-" $+ (L.S.Month) "02" $IntToStrEnh $+ "-" $+ (L.S.Year) $IntToStr $+ (S.$.6000p_Data)
	
	"" (S.$.6000p_login)

	(L.L.dt) 0 >=
	(L.L.dt) 1 < &&
	{if}
		"Montag"
	{else}
	(L.L.dt) 1 >=
	(L.L.dt) 2 < &&
	{if}
		"Dienstag"
	{else}
	(L.L.dt) 2 >=
	(L.L.dt) 3 < &&
	{if}
		"Mittwoch"
	{else}
	(L.L.dt) 3 >=
	(L.L.dt) 4 < &&
	{if}
		"Donnerstag"
	{else}
	(L.L.dt) 4 >=
	(L.L.dt) 5 < &&
	{if}
		"Freitag"
	{else}
	(L.L.dt) 5 >=
	(L.L.dt) 6 < &&
	{if}
		"Samstag"
	{else}
	(L.L.dt) 6 >=
	(L.L.dt) 7 < &&
	{if}
		"Sonntag"
	{endif}
	{endif}
	{endif}
	{endif}
	{endif}
	{endif}
	{endif}
	(S.$.6000p_DzienTygodnia)
	
	(L.L.6000p_menu) 1 =		
	(L.L.6000p_jazda) 1 = ||
	(L.L.6000p_jazda) 2 = ||
	(L.L.6000p_jazda) 3 = ||	
	{if}
		1 (S.L.6000p_ikonagps)
		1 (S.L.6000p_ikonakasownika)
		1 (S.L.6000p_ikonazalogowany)
		1 (S.L.6000p_ikonamodul)
	{else}
		0 (S.L.6000p_ikonagps)
		0 (S.L.6000p_ikonakasownika)
		0 (S.L.6000p_ikonazalogowany)
		0 (S.L.6000p_ikonamodul)		
	{endif}

	(L.L.6000p_jazda) 1 =
	(L.L.6000p_jazda) 2 = ||	
	{if}
		1 (S.L.6000p_ikonastrefy)
	{else}
		0 (S.L.6000p_ikonastrefy)
	{endif}	
	
	(L.L.Przystanek) 2 =
	{if}
		0.5 (S.L.6000p_pozstrefa)
	{else}
		(L.L.door_light_1) (L.L.door_light_2) (L.L.door_light_3) (L.L.door_light_4) || || ||
		{if}
			0 (S.L.6000p_pozstrefa)		
		{else}
			(L.L.Przystanek) 0 =
			{if}		
				0.25 (S.L.6000p_pozstrefa)
			{endif}
		{endif}
	{endif}
	
	(L.L.6000p_blokada) 0 =
	{if}
		0 (S.L.6000p_pozkasownik)
	{else}
		0.25 (S.L.6000p_pozkasownik)
	{endif}

	(L.L.6000p_kurs) 1 =
	(L.L.6000p_kurs) 3 = ||	
	(L.L.6000p_wkursu_rj) 1 = ||
	(L.L.6000p_jazda) 1 = ||
	(L.L.6000p_jazda) 2 = ||	
	{if}
		(L.L.schedule_active) 1 =
		{if}
		{else}
			2 (S.L.6000p_kurs)
			0 (S.L.6000p_wkursu_rj)
			0 (S.L.6000p_jazda)
			0 (S.L.6000p_jazdazrj)	
			0 (S.L.IBIS_TerminusIndex)
			"" (S.$.Matrix_Nr)
			"6kP\6000p_e_kurs2.dds" (S.$.6000p_ekran)
		{endif}
	{endif}	
	
	(L.L.door_light_1) (L.L.door_light_2) (L.L.door_light_3) (L.L.door_light_4) || || ||
	{if}
		(L.L.6000p_aktywnyostatni) 1 =
		{if}
			1 (S.L.6000p_jazda)
			1 (S.L.6000p_jazdazrj)
			0 (S.L.BylOdjazd)
			1 (S.L.6000p_wkursu_nrprzystanku)
			"6kP\6000p_e_jazda.dds" (S.$.6000p_ekran)
			(M.V.GetTTLineString) (S.$.Matrix_Nr) $StrToFloat 100 * (S.L.IBIS_Linie_Complex) (M.V.GetRouteIndex) (S.L.IBIS_RouteIndex)
			(M.V.GetTTLineString) (S.$.Matrix_Nr)
			(M.V.GetTTTerminusIndex) (S.L.IBIS_TerminusIndex) 
			(M.L.IBIS_RefreshBusstop)
			0 (S.L.6000p_ostatni)			
		{endif}
	{endif}
	
	(L.L.6000p_zalogowacjako) 1 =
	{if}
		"Fahrernummer@(" (L.$.6000p_loginID_text) $+ ")" $+ (S.$.6000p_zalogowacjako)
	{endif}

	(L.L.6000p_kurs) 1 =
	{if}
		(M.V.GetTTLineString) (S.$.6000p_KursLinia)
		(L.L.dt) 5 >=
		(L.L.dt) 6 < &&
		{if}
			"12"
		{else}
			(L.L.dt) 6 >=
			(L.L.dt) 7 < &&
			{if}
				"13"
			{else}
				"11"
			{endif}
		{endif}
		(S.$.6000p_TypDnia)
	{endif}
	(L.L.6000p_kurs) 3 =
	{if}
		(L.$.6000p_nrBryg) (S.$.6000p_KursLinia)
		(L.L.dt) 5 >=
		(L.L.dt) 6 < &&
		{if}
			"12"
		{else}
			(L.L.dt) 6 >=
			(L.L.dt) 7 < &&
			{if}
				"13"
			{else}
				"11"
			{endif}
		{endif}
		(S.$.6000p_TypDnia)
	{endif}	

	(M.V.GetTTBusstopIndex) -1 =
	{if}
		(M.V.GetTTBusstopIndex) (S.L.current_stopindex)
	{endif}

	(L.L.current_stopindex) (M.V.GetTTBusstopIndex) = ! 
	{if}
		(L.L.current_stopindex) -1 =
		{if}
			(M.V.GetTTBusstopIndex) (S.L.current_stopindex)
		{else}
			1 (S.L.IBIS_State)
			(L.L.kmcounter_m) (S.L.meter_startwert)
			(M.V.GetTTBusstopIndex) (S.L.current_stopindex)
		{endif}
	{endif}
	
	(L.L.kmcounter_m) (L.L.meter_startwert) - 30 > (L.L.IBIS_State) 1 = &&
	{if}
		(L.L.6000p_wkursu_nrprzystanku) 1 - (M.V.GetTTBusstopIndex) =
		{if}
			0 (S.L.IBIS_State)
		{else}
			(L.L.6000p_wkursu_nrprzystanku) 1 + (S.L.6000p_wkursu_nrprzystanku)		
			(M.L.IBIS_RefreshBusstop)
			(M.L.NastepnyPrzystanekZapowiedz)			
			2 (S.L.Przystanek)
			0 (S.L.IBIS_State)				
		{endif}
	{endif}


	(L.L.kmcounter_m) (L.L.meter_startwert) - 0 < (L.L.IBIS_State) 1 = &&
	{if}
		(L.L.6000p_wkursu_nrprzystanku) 1 + (S.L.6000p_wkursu_nrprzystanku)			
		(M.L.IBIS_RefreshBusstop)	
		(M.L.NastepnyPrzystanekZapowiedz)
		2 (S.L.Przystanek)
		0 (S.L.IBIS_State)	
	{endif}
	
	(M.V.GetTTBusstopIndex) (M.V.GetTTBusstopArr) (L.S.Time) - (M.V.GetTTDelay) + 12 < (L.L.Przystanek) 2 = &&
	{if}
		(M.L.AktualnyPrzystanekZapowiedz)
		(M.V.GetTTBusstopCount) (L.L.6000p_wkursu_nrprzystanku) <=
		{if}
			1 (S.L.6000p_ostatni)
			1 (S.L.6000p_aktywnyostatni)
			(T.L.6000p_piep)
		{endif}
		0 (S.L.Przystanek)
	{endif}	

	(L.L.6000p_wkursu) 1 =
	{if}
		"TEST" (S.$.6000p_wkursu_kier)
		"TEST" (S.$.6000p_wkursu_pocz)
		"TEST" (S.$.6000p_wkursu_info)
	{endif}
	
	(L.L.6000p_wkursu_rj) 1 =
	{if}
		(M.V.GetTTBusstopCount) 1 - (M.V.GetTTBusstopName) (S.$.6000p_wkursu_kier)
		(L.L.6000p_wkursu_nrprzystanku) 1 - (M.V.GetTTBusstopName) (S.$.6000p_wkursu_pocz)
		(L.L.6000p_wkursu_nrprzystanku) $IntToStr "/" $+ (M.V.GetTTBusstopCount) $IntToStr $+ "(" $+ 	
		(L.L.schedule_active) 1 = 
		{if}
			(L.L.6000p_wkursu_nrprzystanku) 1 - (M.V.GetTTBusstopDep) 86400 % 3600 / trunc abs s0 l0 $IntToStr ":" $+ 
			(L.L.6000p_wkursu_nrprzystanku) 1 - (M.V.GetTTBusstopDep) 86400 % 60 / 
			(L.L.6000p_wkursu_nrprzystanku) 1 - (M.V.GetTTBusstopDep) 86400 % 3600 / trunc abs 60 * -
			"02" $IntToStrEnh $+ 
		{else}
			"--:--" 
		{endif} $+ ")" $+ (S.$.6000p_wkursu_info)
	{endif}

	(L.L.6000p_rozpoczeto) 1 =
	{if}
		(L.L.liczenie4) (L.S.Timegap) + (S.L.liczenie4)
		(L.L.liczenie4) 2 >=
		{if}
			0 (S.L.6000p_rozpoczeto)
			0 (S.L.liczenie4)
		{endif}
	{endif}
	
	(L.L.6000p_aktywnyostatni) 1 =
	{if}
		(L.S.Time) 0 (M.V.GetTTBusstopDep) - 0 <
		{if}
			0 (S.L.6000p_aktywnyostatni)
		{endif}
	{endif}	
	
	(L.S.Time) 0 (M.V.GetTTBusstopDep) - 0 >
	(L.L.schedule_active) 1 = &&
	(L.L.6000p_aktywnyostatni) 0 = &&
	{if}
		(L.L.BylOdjazd) 0 =
		{if}
			1 (S.L.6000p_rozpoczeto)
			1 (S.L.BylOdjazd)
			(T.L.6000p_start)
		{endif}	
	{endif}
	
	(L.L.6000p_jazda) 1 =
	{if}
		(L.L.6000p_jazdazrj) 1 =
		{if}
			(L.L.IBIS_TerminusIndex) (M.V.GetTTTerminusIndex) = !
			{if}
				(M.V.GetTTTerminusIndex) (S.L.IBIS_TerminusIndex)
			{endif}
			(M.V.GetTTBusstopCount) 1 - (M.V.GetTTBusstopName) (S.$.6000p_Kierunek)
			(M.V.GetTTLineString) "/" $+ (L.$.6000p_nrBryg) $+ (S.$.6000p_LiniaBrygada)
			(L.L.6000p_wkursu_nrprzystanku) $IntToStr "/" $+ (M.V.GetTTBusstopCount) $IntToStr $+ (S.$.6000p_IloscPrzystankow)
			(L.L.6000p_wkursu_nrprzystanku) 1 - (M.V.GetTTBusstopName) "@" $+ "(Information: --)" $+ (S.$.6000p_Przystanek)
			(L.L.BylOdjazd) 0 =
			{if}
				(L.L.liczenie2) (L.S.Timegap) + (S.L.liczenie2)
				(L.L.liczenie2) 1 >=
				{if}
					(L.S.Time) (L.L.6000p_wkursu_nrprzystanku) 1 - (M.V.GetTTBusstopDep) - 0 <
					{if}
						"+"
					{else}
						"-"
					{endif}
					(L.L.6000p_wkursu_nrprzystanku) (M.V.GetTTBusstopCount) =
					{if}
						(L.S.Time) (L.L.6000p_wkursu_nrprzystanku) 1 - (M.V.GetTTBusstopArr) - 60 / trunc abs $IntToStr $+ ":" $+
						(L.S.Time) (L.L.6000p_wkursu_nrprzystanku) 1 - (M.V.GetTTBusstopArr) - 60 / s6 l6 trunc s7 l6 l7 - 60 * trunc abs "02" $IntToStrEnh $+ (S.$.6000p_opoznienie)
					{else}
						(L.S.Time) (L.L.6000p_wkursu_nrprzystanku) 1 - (M.V.GetTTBusstopDep) - 60 / trunc abs $IntToStr $+ ":" $+
						(L.S.Time) (L.L.6000p_wkursu_nrprzystanku) 1 - (M.V.GetTTBusstopDep) - 60 / s6 l6 trunc s7 l6 l7 - 60 * trunc abs "02" $IntToStrEnh $+ (S.$.6000p_opoznienie)
					{endif}
					(L.L.liczenie3) (L.S.Timegap) + (S.L.liczenie3)
					(L.L.liczenie3) 1 >=
					{if}
						0 (S.L.liczenie2)
						0 (S.L.liczenie3)
					{endif}
				{else}
					"" (S.$.6000p_opoznienie)
				{endif}	
			{else}
				(L.S.Time) (L.L.6000p_wkursu_nrprzystanku) 1 - (M.V.GetTTBusstopDep) - 0 <
				{if}
					"+"
				{else}
					"-"
				{endif}
				(L.L.6000p_wkursu_nrprzystanku) (M.V.GetTTBusstopCount) =
				{if}
					(L.S.Time) (L.L.6000p_wkursu_nrprzystanku) 1 - (M.V.GetTTBusstopArr) - 60 / trunc abs $IntToStr $+ ":" $+
					(L.S.Time) (L.L.6000p_wkursu_nrprzystanku) 1 - (M.V.GetTTBusstopArr) - 60 / s6 l6 trunc s7 l6 l7 - 60 * trunc abs "02" $IntToStrEnh $+ (S.$.6000p_opoznienie)
				{else}
					(L.S.Time) (L.L.6000p_wkursu_nrprzystanku) 1 - (M.V.GetTTBusstopDep) - 60 / trunc abs $IntToStr $+ ":" $+
					(L.S.Time) (L.L.6000p_wkursu_nrprzystanku) 1 - (M.V.GetTTBusstopDep) - 60 / s6 l6 trunc s7 l6 l7 - 60 * trunc abs "02" $IntToStrEnh $+ (S.$.6000p_opoznienie)
				{endif}	
			{endif}
			(L.L.6000p_wkursu_nrprzystanku) 1 + (M.V.GetTTBusstopCount) <=
			{if}
				(L.L.6000p_wkursu_nrprzystanku) 1 + (M.V.GetTTBusstopCount) =
				{if}
					(L.L.6000p_wkursu_nrprzystanku) (M.V.GetTTBusstopArr) 86400 % 3600 / trunc abs s0 l0 $IntToStr ":" $+ 
					(L.L.6000p_wkursu_nrprzystanku) (M.V.GetTTBusstopArr) 86400 % 60 / 
					(L.L.6000p_wkursu_nrprzystanku) (M.V.GetTTBusstopArr) 86400 % 3600 / trunc abs 60 * -
					"02" $IntToStrEnh $+ " " $+ (L.L.6000p_wkursu_nrprzystanku) (M.V.GetTTBusstopName) $+ (S.$.6000p_nastepny)
				{else}
					(L.L.6000p_wkursu_nrprzystanku) (M.V.GetTTBusstopDep) 86400 % 3600 / trunc abs s0 l0 $IntToStr ":" $+ 
					(L.L.6000p_wkursu_nrprzystanku) (M.V.GetTTBusstopDep) 86400 % 60 / 
					(L.L.6000p_wkursu_nrprzystanku) (M.V.GetTTBusstopDep) 86400 % 3600 / trunc abs 60 * -
					"02" $IntToStrEnh $+ " " $+ (L.L.6000p_wkursu_nrprzystanku) (M.V.GetTTBusstopName) $+ (S.$.6000p_nastepny)
				{endif}
			{else}
				"---" (S.$.6000p_nastepny)
			{endif}
			(L.L.6000p_wkursu_nrprzystanku) 2 + (M.V.GetTTBusstopCount) <=
			{if}
				(L.L.6000p_wkursu_nrprzystanku) 2 + (M.V.GetTTBusstopCount) =
				{if}
					(L.L.6000p_wkursu_nrprzystanku) 1 + (M.V.GetTTBusstopArr) 86400 % 3600 / trunc abs s0 l0 $IntToStr ":" $+ 
					(L.L.6000p_wkursu_nrprzystanku) 1 + (M.V.GetTTBusstopArr) 86400 % 60 / 
					(L.L.6000p_wkursu_nrprzystanku) 1 + (M.V.GetTTBusstopArr) 86400 % 3600 / trunc abs 60 * -
					"02" $IntToStrEnh $+ " " $+ (L.L.6000p_wkursu_nrprzystanku) 1 + (M.V.GetTTBusstopName) $+ (S.$.6000p_nastepnynastepny)
				{else}
					(L.L.6000p_wkursu_nrprzystanku) 1 + (M.V.GetTTBusstopDep) 86400 % 3600 / trunc abs s0 l0 $IntToStr ":" $+ 
					(L.L.6000p_wkursu_nrprzystanku) 1 + (M.V.GetTTBusstopDep) 86400 % 60 / 
					(L.L.6000p_wkursu_nrprzystanku) 1 + (M.V.GetTTBusstopDep) 86400 % 3600 / trunc abs 60 * -
					"02" $IntToStrEnh $+ " " $+ (L.L.6000p_wkursu_nrprzystanku) 1 + (M.V.GetTTBusstopName) $+ (S.$.6000p_nastepnynastepny)
				{endif}
			{else}
				"---" (S.$.6000p_nastepnynastepny)	
			{endif}			
		{endif}
	{endif}
	
	(L.L.6000p_jazda) 2 =
	{if}
		(L.L.6000p_jazdazrj) 1 =
		{if}
			(L.L.IBIS_TerminusIndex) (M.V.GetTTTerminusIndex) = !
			{if}
				(M.V.GetTTTerminusIndex) (S.L.IBIS_TerminusIndex)
			{endif}		
			(M.V.GetTTBusstopCount) 1 - (M.V.GetTTBusstopName) (S.$.6000p_Kierunek)
			(M.V.GetTTLineString) "/" $+ (L.$.6000p_nrBryg) $+ (S.$.6000p_LiniaBrygada)
			(L.L.6000p_wkursu_nrprzystanku_temp) $IntToStr "/" $+ (M.V.GetTTBusstopCount) $IntToStr $+ (S.$.6000p_IloscPrzystankow)
			(L.L.6000p_wkursu_nrprzystanku_temp) 1 - (M.V.GetTTBusstopName) "@" $+ "(Brak informacji o ulicy)" $+ (S.$.6000p_Przystanek)
			(L.L.BylOdjazd) 0 =
			{if}
				(L.L.liczenie2) (L.S.Timegap) + (S.L.liczenie2)
				(L.L.liczenie2) 1 >=
				{if}
					(L.S.Time) (L.L.6000p_wkursu_nrprzystanku_temp) 1 - (M.V.GetTTBusstopDep) - 0 <
					{if}
						"+"
					{else}
						"-"
					{endif}
					(L.L.6000p_wkursu_nrprzystanku_temp) (M.V.GetTTBusstopCount) =
					{if}
						(L.S.Time) (L.L.6000p_wkursu_nrprzystanku_temp) 1 - (M.V.GetTTBusstopArr) - 60 / trunc abs $IntToStr $+ ":" $+
						(L.S.Time) (L.L.6000p_wkursu_nrprzystanku_temp) 1 - (M.V.GetTTBusstopArr) - 60 / s6 l6 trunc s7 l6 l7 - 60 * trunc abs "02" $IntToStrEnh $+ (S.$.6000p_opoznienie)
					{else}
						(L.S.Time) (L.L.6000p_wkursu_nrprzystanku_temp) 1 - (M.V.GetTTBusstopDep) - 60 / trunc abs $IntToStr $+ ":" $+
						(L.S.Time) (L.L.6000p_wkursu_nrprzystanku_temp) 1 - (M.V.GetTTBusstopDep) - 60 / s6 l6 trunc s7 l6 l7 - 60 * trunc abs "02" $IntToStrEnh $+ (S.$.6000p_opoznienie)
					{endif}
					(L.L.liczenie3) (L.S.Timegap) + (S.L.liczenie3)
					(L.L.liczenie3) 1 >=
					{if}
						0 (S.L.liczenie2)
						0 (S.L.liczenie3)
					{endif}
				{else}
					"" (S.$.6000p_opoznienie)
				{endif}	
			{else}
				(L.S.Time) (L.L.6000p_wkursu_nrprzystanku_temp) 1 - (M.V.GetTTBusstopDep) - 0 <
				{if}
					"+"
				{else}
					"-"
				{endif}
				(L.L.6000p_wkursu_nrprzystanku_temp) (M.V.GetTTBusstopCount) =
				{if}
					(L.S.Time) (L.L.6000p_wkursu_nrprzystanku_temp) 1 - (M.V.GetTTBusstopArr) - 60 / trunc abs $IntToStr $+ ":" $+
					(L.S.Time) (L.L.6000p_wkursu_nrprzystanku_temp) 1 - (M.V.GetTTBusstopArr) - 60 / s6 l6 trunc s7 l6 l7 - 60 * trunc abs "02" $IntToStrEnh $+ (S.$.6000p_opoznienie)
				{else}
					(L.S.Time) (L.L.6000p_wkursu_nrprzystanku_temp) 1 - (M.V.GetTTBusstopDep) - 60 / trunc abs $IntToStr $+ ":" $+
					(L.S.Time) (L.L.6000p_wkursu_nrprzystanku_temp) 1 - (M.V.GetTTBusstopDep) - 60 / s6 l6 trunc s7 l6 l7 - 60 * trunc abs "02" $IntToStrEnh $+ (S.$.6000p_opoznienie)
				{endif}	
			{endif}
			(L.L.6000p_wkursu_nrprzystanku_temp) 1 + (M.V.GetTTBusstopCount) <=
			{if}
				(L.L.6000p_wkursu_nrprzystanku_temp) 1 + (M.V.GetTTBusstopCount) =
				{if}
					(L.L.6000p_wkursu_nrprzystanku_temp) (M.V.GetTTBusstopArr) 86400 % 3600 / trunc abs s0 l0 $IntToStr ":" $+ 
					(L.L.6000p_wkursu_nrprzystanku_temp) (M.V.GetTTBusstopArr) 86400 % 60 / 
					(L.L.6000p_wkursu_nrprzystanku_temp) (M.V.GetTTBusstopArr) 86400 % 3600 / trunc abs 60 * -
					"02" $IntToStrEnh $+ " " $+ (L.L.6000p_wkursu_nrprzystanku_temp) (M.V.GetTTBusstopName) $+ (S.$.6000p_nastepny)
				{else}
					(L.L.6000p_wkursu_nrprzystanku_temp) (M.V.GetTTBusstopDep) 86400 % 3600 / trunc abs s0 l0 $IntToStr ":" $+ 
					(L.L.6000p_wkursu_nrprzystanku_temp) (M.V.GetTTBusstopDep) 86400 % 60 / 
					(L.L.6000p_wkursu_nrprzystanku_temp) (M.V.GetTTBusstopDep) 86400 % 3600 / trunc abs 60 * -
					"02" $IntToStrEnh $+ " " $+ (L.L.6000p_wkursu_nrprzystanku_temp) (M.V.GetTTBusstopName) $+ (S.$.6000p_nastepny)
				{endif}
			{else}
				"---" (S.$.6000p_nastepny)
			{endif}
			(L.L.6000p_wkursu_nrprzystanku_temp) 2 + (M.V.GetTTBusstopCount) <=
			{if}
				(L.L.6000p_wkursu_nrprzystanku_temp) 2 + (M.V.GetTTBusstopCount) =
				{if}
					(L.L.6000p_wkursu_nrprzystanku_temp) 1 + (M.V.GetTTBusstopArr) 86400 % 3600 / trunc abs s0 l0 $IntToStr ":" $+ 
					(L.L.6000p_wkursu_nrprzystanku_temp) 1 + (M.V.GetTTBusstopArr) 86400 % 60 / 
					(L.L.6000p_wkursu_nrprzystanku_temp) 1 + (M.V.GetTTBusstopArr) 86400 % 3600 / trunc abs 60 * -
					"02" $IntToStrEnh $+ " " $+ (L.L.6000p_wkursu_nrprzystanku_temp) 1 + (M.V.GetTTBusstopName) $+ (S.$.6000p_nastepnynastepny)
				{else}
					(L.L.6000p_wkursu_nrprzystanku_temp) 1 + (M.V.GetTTBusstopDep) 86400 % 3600 / trunc abs s0 l0 $IntToStr ":" $+ 
					(L.L.6000p_wkursu_nrprzystanku_temp) 1 + (M.V.GetTTBusstopDep) 86400 % 60 / 
					(L.L.6000p_wkursu_nrprzystanku_temp) 1 + (M.V.GetTTBusstopDep) 86400 % 3600 / trunc abs 60 * -
					"02" $IntToStrEnh $+ " " $+ (L.L.6000p_wkursu_nrprzystanku_temp) 1 + (M.V.GetTTBusstopName) $+ (S.$.6000p_nastepnynastepny)
				{endif}
			{else}
				"---" (S.$.6000p_nastepnynastepny)	
			{endif}			
		{endif}
	{endif}	
	
	(L.L.6000p_jazda) 3 =
	{if}
		(L.L.IBIS_TerminusIndex) 5 (M.V.GetTerminusString) (S.$.6000p_Kierunek)
		(L.$.6000p_linia) "/" $+ (L.$.6000p_kieruneknr) $+ (S.$.6000p_LiniaBrygada)
		"" (S.$.6000p_opoznienie)
		"" (S.$.6000p_nastepny)
		"" (S.$.6000p_nastepnynastepny)
		"" (S.$.6000p_IloscPrzystankow)		
		"" (S.$.6000p_Przystanek)
	{endif}	
{else}
	0 (S.L.6000p_brygada)
	0 (S.L.uruchomiony)
	0 (S.L.boot_mode)
	0 (S.L.liczenie1)
	0 (S.L.6000p_loginID)
	0 (S.L.6000p_klawiatura)
	0 (S.L.6000p_zalogowacjako)
	0 (S.L.6000p_rozpoczeto)	
	0 (S.L.6000p_menu)
	0 (S.L.6000p_kurs)
	0 (S.L.6000p_wkursu)
	0 (S.L.6000p_jazda)	
	0 (S.L.6000p_jazdazrj)		
	0 (S.L.6000p_wkursu_rj)
	0 (S.L.6000p_ostatni)
	0 (S.L.6000p_aktywnyostatni)	
	1 (S.L.wylaczony)
	0 (S.L.6000p_ikonagps)
	0 (S.L.6000p_ikonakasownika)
	0 (S.L.6000p_ikonazalogowany)
	0 (S.L.6000p_ikonamodul)	
	0 (S.L.6000p_ikonastrefy)	
	0 (S.L.IBIS_TerminusIndex)
	0 (S.L.IBIS_Linie_Complex)
	"" (S.$.Matrix_Nr)
	"" (S.$.RG_brygadowka)
	"6kP\6000p_e.dds" (S.$.6000p_ekran)
{endif}

1 (S.L.Refresh_Strings)

{end}

'#########################
'TRIGGERY
'#########################

{trigger:6000p_loginID_text}
(L.L.6000p_loginID) 1 =
{if}
	2 (S.L.6000p_loginID)
	1 (S.L.6000p_klawiatura)
	"6kP\6000p_e_klawiatura.dds" (S.$.6000p_ekran)
	(L.$.6000p_loginID_text) (S.$.6000p_klawiatura)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_loginID_akceptuj}
(L.L.6000p_loginID) 1 =
{if}
	0 (S.L.6000p_loginID)
	1 (S.L.6000p_zalogowacjako)
	"6kP\6000p_e_zalogowacjako.dds" (S.$.6000p_ekran)
	(T.L.6000p_piep)	
{endif}
{end}

{trigger:6000p_loginID_odrzuc}
(L.L.6000p_loginID) 1 =
{if}
	"" (S.$.6000p_loginID_text)
	(T.L.6000p_piep)	
{endif}
{end}

{trigger:6000p_zalogowacjako_tak}
(L.L.6000p_zalogowacjako) 1 =
{if}
	0 (S.L.6000p_zalogowacjako)
	1 (S.L.6000p_menu)
	"6kP\6000p_e_menu1.dds" (S.$.6000p_ekran)
	(T.L.6000p_piep)	
{endif}
(L.L.6000p_wymelduj) 1 =
{if}
	0 (S.L.6000p_wymelduj)
	0 (S.L.IBIS_TerminusIndex)
	"" (S.$.Matrix_Nr)
	1 (S.L.6000p_menu)
	0 (S.L.6000p_jazdazrj)
	0 (S.L.6000p_jakajazda)	
	"6kP\6000p_e_menu1.dds" (S.$.6000p_ekran)
	(T.L.6000p_piep)	
{endif}
(L.L.6000p_zmienkurs) 1 =
{if}
	0 (S.L.6000p_zmienkurs)
	0 (S.L.IBIS_TerminusIndex)
	"" (S.$.Matrix_Nr)	
	1 (S.L.6000p_kurs)
	0 (S.L.6000p_jazdazrj)
	0 (S.L.6000p_jakajazda)
	"6kP\6000p_e_kurs1.dds" (S.$.6000p_ekran)
	(T.L.6000p_piep)	
{endif}
{end}

{trigger:6000p_zalogowacjako_nie}
(L.L.6000p_zalogowacjako) 1 =
{if}
	1 (S.L.6000p_loginID)
	0 (S.L.6000p_zalogowacjako)
	"6kP\6000p_e_loginID.dds" (S.$.6000p_ekran)
	(T.L.6000p_piep)
{endif}
(L.L.6000p_wymelduj) 1 =
{if}
	(L.L.6000p_jakajazda) 1 =
	{if}
		1 (S.L.6000p_jazda)
		1 (S.L.6000p_jazdazrj)
		0 (S.L.6000p_wymelduj)		
		"6kP\6000p_e_jazda.dds" (S.$.6000p_ekran)
		(T.L.6000p_piep)		
	{endif}
	(L.L.6000p_jakajazda) 2 =
	{if}
		2 (S.L.6000p_jazda)
		1 (S.L.6000p_jazdazrj)	
		0 (S.L.6000p_wymelduj)		
		"6kP\6000p_e_jazda_korekta.dds" (S.$.6000p_ekran)
		(T.L.6000p_piep)
	{endif}
	(L.L.6000p_jakajazda) 3 =
	{if}
		3 (S.L.6000p_jazda)
		0 (S.L.6000p_jazdazrj)
		0 (S.L.6000p_wymelduj)
		"6kP\6000p_e_jazdald.dds" (S.$.6000p_ekran)		
		(T.L.6000p_piep)
	{endif}	
{endif}
(L.L.6000p_zmienkurs) 1 =
{if}
	(L.L.6000p_jakajazda) 1 =
	{if}
		1 (S.L.6000p_jazda)
		0 (S.L.6000p_zmienkurs)
		1 (S.L.6000p_jazdazrj)	
		"6kP\6000p_e_jazda.dds" (S.$.6000p_ekran)
		(T.L.6000p_piep)
	{endif}
	(L.L.6000p_jakajazda) 2 =
	{if}
		2 (S.L.6000p_jazda)
		0 (S.L.6000p_zmienkurs)
		1 (S.L.6000p_jazdazrj)	
		"6kP\6000p_e_jazda_korekta.dds" (S.$.6000p_ekran)
		(T.L.6000p_piep)
	{endif}
	(L.L.6000p_jakajazda) 3 =
	{if}
		3 (S.L.6000p_jazda)
		0 (S.L.6000p_zmienkurs)
		0 (S.L.6000p_jazdazrj)	
		"6kP\6000p_e_jazdald.dds" (S.$.6000p_ekran)	
		(T.L.6000p_piep)
	{endif}	
{endif}
{end}

{trigger:6000p_klawiatura_1}
(L.L.6000p_klawiatura) 1 =
{if}
	(L.$.6000p_klawiatura) "1" $+ (S.$.6000p_klawiatura)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_klawiatura_2}
(L.L.6000p_klawiatura) 1 =
{if}
	(L.$.6000p_klawiatura) "2" $+ (S.$.6000p_klawiatura)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_klawiatura_3}
(L.L.6000p_klawiatura) 1 =
{if}
	(L.$.6000p_klawiatura) "3" $+ (S.$.6000p_klawiatura)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_klawiatura_4}
(L.L.6000p_klawiatura) 1 =
{if}
	(L.$.6000p_klawiatura) "4" $+ (S.$.6000p_klawiatura)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_klawiatura_5}
(L.L.6000p_klawiatura) 1 =
{if}
	(L.$.6000p_klawiatura) "5" $+ (S.$.6000p_klawiatura)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_klawiatura_6}
(L.L.6000p_klawiatura) 1 =
{if}
	(L.$.6000p_klawiatura) "6" $+ (S.$.6000p_klawiatura)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_klawiatura_7}
(L.L.6000p_klawiatura) 1 =
{if}
	(L.$.6000p_klawiatura) "7" $+ (S.$.6000p_klawiatura)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_klawiatura_8}
(L.L.6000p_klawiatura) 1 =
{if}
	(L.$.6000p_klawiatura) "8" $+ (S.$.6000p_klawiatura)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_klawiatura_9}
(L.L.6000p_klawiatura) 1 =
{if}
	(L.$.6000p_klawiatura) "9" $+ (S.$.6000p_klawiatura)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_klawiatura_0}
(L.L.6000p_klawiatura) 1 =
{if}
	(L.$.6000p_klawiatura) "0" $+ (S.$.6000p_klawiatura)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_klawiatura_backspace}
(L.L.6000p_klawiatura) 1 =
{if}
	(L.$.6000p_klawiatura) 1 $cutEnd (S.$.6000p_klawiatura)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_klawiatura_akceptuj}
(L.L.6000p_klawiatura) 1 =
(L.L.6000p_loginID) 2 = &&
{if}
	1 (S.L.6000p_loginID)
	0 (S.L.6000p_klawiatura)
	"6kP\6000p_e_loginID.dds" (S.$.6000p_ekran)
	(L.$.6000p_klawiatura) (S.$.6000p_loginID_text)
	(T.L.6000p_piep)
{endif}
(L.L.6000p_klawiatura) 1 =
(L.L.6000p_brygada) 1 = &&
{if}
	3 (S.L.6000p_kurs)
	0 (S.L.6000p_klawiatura)
	0 (S.L.6000p_brygada)		
	"6kP\6000p_e_kurs1_b.dds" (S.$.6000p_ekran)
	(L.$.6000p_klawiatura) (S.$.6000p_nrBryg)
	(T.L.6000p_piep)
{endif}
(L.L.6000p_klawiatura) 1 =
(L.L.6000p_linia) 1 = &&
{if}
	2 (S.L.6000p_kurs)
	0 (S.L.6000p_klawiatura)
	0 (S.L.6000p_linia)	
	"6kP\6000p_e_kurs2.dds" (S.$.6000p_ekran)
	(L.$.6000p_klawiatura) (S.$.6000p_Linia)
	(T.L.6000p_piep)
{endif}
(L.L.6000p_klawiatura) 1 =
(L.L.6000p_kierunek) 1 = &&
{if}
	2 (S.L.6000p_kurs)
	0 (S.L.6000p_kierunek)
	0 (S.L.6000p_klawiatura)
	"6kP\6000p_e_kurs2.dds" (S.$.6000p_ekran)
	(L.$.6000p_klawiatura) (S.$.6000p_Kieruneknr)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_klawiatura_odrzuc}
(L.L.6000p_klawiatura) 1 =
(L.L.6000p_loginID) 2 = &&
{if}
	1 (S.L.6000p_loginID)
	0 (S.L.6000p_klawiatura)
	"6kP\6000p_e_loginID.dds" (S.$.6000p_ekran)
	(T.L.6000p_piep)
{endif}
(L.L.6000p_klawiatura) 1 =
(L.L.6000p_brygada) 1 = &&
{if}
	3 (S.L.6000p_kurs)
	0 (S.L.6000p_brygada)	
	0 (S.L.6000p_klawiatura)
	"6kP\6000p_e_kurs1_b.dds" (S.$.6000p_ekran)
	(T.L.6000p_piep)
{endif}
(L.L.6000p_klawiatura) 1 =
(L.L.6000p_linia) 1 = &&
{if}
	2 (S.L.6000p_kurs)
	0 (S.L.6000p_klawiatura)
	"6kP\6000p_e_kurs2.dds" (S.$.6000p_ekran)
	(T.L.6000p_piep)
{endif}
(L.L.6000p_klawiatura) 1 =
(L.L.6000p_kierunek) 1 = &&
{if}
	2 (S.L.6000p_kurs)
	0 (S.L.6000p_klawiatura)
	"6kP\6000p_e_kurs2.dds" (S.$.6000p_ekran)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_przycisk1}
(L.L.6000p_kurs) 1 =
(L.L.6000p_kurs) 2 = ||
{if}
	1 (S.L.6000p_menu)
	0 (S.L.6000p_kurs)
	"6kP\6000p_e_menu1.dds" (S.$.6000p_ekran)
	(T.L.6000p_piep)
{else}
	(L.L.6000p_menu) 1 =
	{if}
		(L.L.schedule_active) 1 = &&
		{if}
			0 (S.L.6000p_menu)
			1 (S.L.6000p_kurs)
			"6kP\6000p_e_kurs1.dds" (S.$.6000p_ekran)
			(T.L.6000p_piep)
		{else}
			0 (S.L.6000p_menu)
			2 (S.L.6000p_kurs)
			"6kP\6000p_e_kurs2.dds" (S.$.6000p_ekran)
			(T.L.6000p_piep)
		{endif}
	{endif}
{endif}
(L.L.6000p_kurs) 3 =
{if}
	1 (S.L.6000p_kurs)
	"6kP\6000p_e_kurs1.dds" (S.$.6000p_ekran)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_przycisk2}
(L.L.6000p_jazda) 1 =
(L.L.6000p_jazda) 2 = ||
(L.L.6000p_jazda) 3 = ||
(L.L.6000p_menu) 1 = ||
{if}
	(L.L.6000p_blokada) ! (S.L.6000p_blokada)
	(L.L.6000p_blokada) 0 = 
	{if}
		(M.L.blokada_kasownikow)
	{endif}
	(T.L.6000p_piep)	
{endif}
{end}

{trigger:6000p_przyciskg1}
(L.L.6000p_kurs) 2 =
{if}
	(L.L.schedule_active) 1 =
	{if}
		1 (S.L.6000p_kurs)
		"6kP\6000p_e_kurs1.dds" (S.$.6000p_ekran)
		(T.L.6000p_piep)
	{endif}	
{endif}
{end}

{trigger:6000p_przyciskg2}
(L.L.6000p_kurs) 1 =
{if}
	(L.L.schedule_active) 1 =
	{if}
		2 (S.L.6000p_kurs)
		"6kP\6000p_e_kurs2.dds" (S.$.6000p_ekran)
		(T.L.6000p_piep)
	{endif}	
{endif}
{end}

{trigger:6000p_zatwierdz}
(L.L.6000p_kurs) 3 =
{if}
	0 (S.L.6000p_kurs)
	"6kP\6000p_e_wkursu.dds" (S.$.6000p_ekran)
	1 (S.L.6000p_wkursu_rj)
	1 (S.L.6000p_wkursu_nrprzystanku)
	(T.L.6000p_piep)
{else}
	(L.L.6000p_kurs) 1 =
	{if}
		3 (S.L.6000p_kurs)
		"6kP\6000p_e_kurs1_b.dds" (S.$.6000p_ekran)
		(T.L.6000p_piep)
	{endif}
{endif}
(L.L.6000p_kurs) 2 =
{if}
	(L.$.6000p_linia) $StrToFloat 100 * (S.L.IBIS_Linie_Complex)
	(L.$.6000p_Kieruneknr) $StrToFloat (M.V.GetTerminusIndex) (S.L.IBIS_TerminusIndex)
	3 (S.L.6000p_jazda)
	0 (S.L.6000p_kurs)
	"6kP\6000p_e_jazdald.dds" (S.$.6000p_ekran)	
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_wkursu_powrot}
(L.L.6000p_wkursu_rj) 1 =
{if}
	0 (S.L.6000p_wkursu_rj)
	3 (S.L.6000p_kurs)
	"6kP\6000p_e_kurs1_b.dds" (S.$.6000p_ekran)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_wkursu_wstecz}
(L.L.6000p_wkursu_rj) 1 =
{if}
	(L.L.6000p_wkursu_nrprzystanku) 1 >
	{if}
		(L.L.6000p_wkursu_nrprzystanku) 1 - (S.L.6000p_wkursu_nrprzystanku)
		(T.L.6000p_piep)
	{endif}
{endif}
{end}

{trigger:6000p_wkursu_dalej}
(L.L.6000p_wkursu_rj) 1 =
{if}
	(L.L.6000p_wkursu_nrprzystanku) (M.V.GetTTBusstopCount) <
	{if}
		(L.L.6000p_wkursu_nrprzystanku) 1 + (S.L.6000p_wkursu_nrprzystanku)
		(T.L.6000p_piep)
	{endif}
{endif}
{end}

{trigger:6000p_wkursu_akceptuj}
(L.L.6000p_wkursu_rj) 1 =
{if}
	0 (S.L.6000p_wkursu_rj)
	1 (S.L.6000p_jazda)
	1 (S.L.6000p_jazdazrj)
	0 (S.L.BylOdjazd)
	"6kP\6000p_e_jazda.dds" (S.$.6000p_ekran)
	(M.V.GetTTLineString) (S.$.Matrix_Nr) $StrToFloat 100 * (S.L.IBIS_Linie_Complex) (M.V.GetRouteIndex) (S.L.IBIS_RouteIndex)
	(M.V.GetTTLineString) (S.$.Matrix_Nr)
	(M.V.GetTTTerminusIndex) (S.L.IBIS_TerminusIndex) 
	(M.L.IBIS_RefreshBusstop)
	(T.L.6000p_piep)
{endif}
(L.L.6000p_wkursu) 1 =
{if}
	0 (S.L.6000p_wkursu)
	1 (S.L.6000p_jazda)
	0 (S.L.6000p_jazdazrj)
	"6kP\6000p_e_jazda.dds" (S.$.6000p_ekran)
'	(M.V.GetTTLineString) 100 * (S.L.IBIS_Linie_Complex) (M.V.GetRouteIndex) (S.L.IBIS_RouteIndex)
'	(M.V.GetTTTerminusIndex) (S.L.IBIS_TerminusIndex) 
'	(M.L.IBIS_RefreshBusstop)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_jazda_przystanek}
(L.L.6000p_jazda) 1 =
{if}
	(M.L.AktualnyPrzystanekZapowiedz)
	(T.L.6000p_piep)	
{endif}
{end}

{trigger:6000p_kurs_brygada}
(L.L.6000p_kurs) 3 =
{if}
	0 (S.L.6000p_kurs)
	1 (S.L.6000p_brygada)
	1 (S.L.6000p_klawiatura)
	"6kP\6000p_e_klawiatura.dds" (S.$.6000p_ekran)
	(L.$.6000p_nrBryg) (S.$.6000p_klawiatura)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_kurs_linia}
(L.L.6000p_kurs) 2 =
{if}
	0 (S.L.6000p_kurs)
	1 (S.L.6000p_linia)
	1 (S.L.6000p_klawiatura)
	"6kP\6000p_e_klawiatura.dds" (S.$.6000p_ekran)
	(L.$.6000p_linia) (S.$.6000p_klawiatura)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_kurs_kierunek}
(L.L.6000p_kurs) 2 =
{if}
	0 (S.L.6000p_kurs)
	1 (S.L.6000p_kierunek)
	1 (S.L.6000p_klawiatura)
	"6kP\6000p_e_klawiatura.dds" (S.$.6000p_ekran)
	(L.$.6000p_kieruneknr) (S.$.6000p_klawiatura)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_jazda_zmienkurs}
(L.L.6000p_jazda) 1 =
{if}
	0 (S.L.6000p_jazda)	
	0 (S.L.6000p_jazdazrj)
	1 (S.L.6000p_jakajazda)	
	1 (S.L.6000p_zmienkurs)
	"6kP\6000p_e_przerwanie.dds" (S.$.6000p_ekran)
	(T.L.6000p_piep)
{endif}
(L.L.6000p_jazda) 2 =
{if}
	0 (S.L.6000p_jazda)	
	0 (S.L.6000p_jazdazrj)
	2 (S.L.6000p_jakajazda)
	1 (S.L.6000p_zmienkurs)
	"6kP\6000p_e_przerwanie.dds" (S.$.6000p_ekran)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_jazda_wymelduj}
(L.L.6000p_jazda) 1 =
{if}
	0 (S.L.6000p_jazda)	
	1 (S.L.6000p_jazdazrj)
	1 (S.L.6000p_jakajazda)
	1 (S.L.6000p_wymelduj)
	"6kP\6000p_e_wymeldowac.dds" (S.$.6000p_ekran)
	(T.L.6000p_piep)
{endif}
(L.L.6000p_jazda) 2 =
{if}
	0 (S.L.6000p_jazda)	
	1 (S.L.6000p_jazdazrj)
	2 (S.L.6000p_jakajazda)
	1 (S.L.6000p_wymelduj)
	"6kP\6000p_e_wymeldowac.dds" (S.$.6000p_ekran)
	(T.L.6000p_piep)
{endif}
(L.L.6000p_jazda) 3 =
{if}
	0 (S.L.6000p_jazda)	
	0 (S.L.6000p_jazdazrj)
	3 (S.L.6000p_jakajazda)
	1 (S.L.6000p_wymelduj)
	"6kP\6000p_e_wymeldowac.dds" (S.$.6000p_ekran)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_jazda_odjazd}
(L.L.6000p_jazda) 1 =
{if}
	(L.L.BylOdjazd) 0 =
	{if}
		1 (S.L.BylOdjazd)
		1 (S.L.6000p_rozpoczeto)
		(T.L.6000p_start)
		(T.L.6000p_piep)
	{endif}
{endif}
{end}

{trigger:6000p_jazda_odrzuc}
(L.L.6000p_jazda) 2 =
{if}
	1 (S.L.6000p_jazda)
	"6kP\6000p_e_jazda.dds" (S.$.6000p_ekran)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_jazda_zaakceptuj}
(L.L.6000p_jazda) 2 =
{if}
	1 (S.L.6000p_jazda)
	"6kP\6000p_e_jazda.dds" (S.$.6000p_ekran)
	(L.L.6000p_wkursu_nrprzystanku_temp) (S.L.6000p_wkursu_nrprzystanku)
	(M.L.AktualnyPrzystanekZapowiedz)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_jazda_wstecz}
(L.L.6000p_jazda) 2 =
{if}
	(L.L.6000p_wkursu_nrprzystanku_temp) 1 >
	{if}
		(L.L.6000p_wkursu_nrprzystanku_temp) 1 - (S.L.6000p_wkursu_nrprzystanku_temp)
		(T.L.6000p_piep)
	{endif}
{endif}
(L.L.6000p_jazda) 1 =
{if}
	(L.L.6000p_wkursu_nrprzystanku) 1 >
	{if}
		(L.L.6000p_wkursu_nrprzystanku) 1 - (S.L.6000p_wkursu_nrprzystanku_temp)
		2 (S.L.6000p_jazda)
		"6kP\6000p_e_jazda_korekta.dds" (S.$.6000p_ekran)
		(T.L.6000p_piep)		
	{endif}
{endif}
{end}

{trigger:6000p_jazda_nastepny}
(L.L.6000p_jazda) 2 =
{if}
	(L.L.6000p_aktywnyostatni) 1 =
	{if}
		1 (S.L.6000p_jazda)
		1 (S.L.6000p_jazdazrj)
		0 (S.L.BylOdjazd)
		1 (S.L.6000p_wkursu_nrprzystanku)
		"6kP\6000p_e_jazda.dds" (S.$.6000p_ekran)
		(M.V.GetTTLineString) (S.$.Matrix_Nr) $StrToFloat 100 * (S.L.IBIS_Linie_Complex) (M.V.GetRouteIndex) (S.L.IBIS_RouteIndex)
		(M.V.GetTTLineString) (S.$.Matrix_Nr)
		(M.V.GetTTTerminusIndex) (S.L.IBIS_TerminusIndex) 
		(M.L.IBIS_RefreshBusstop)
		(T.L.6000p_piep)
	{endif}		
	(L.L.6000p_wkursu_nrprzystanku_temp) (M.V.GetTTBusstopCount) <
	{if}
		(L.L.6000p_wkursu_nrprzystanku_temp) 1 + (S.L.6000p_wkursu_nrprzystanku_temp)
		(T.L.6000p_piep)
	{endif}	
{endif}
(L.L.6000p_jazda) 1 =
{if}
	(L.L.6000p_aktywnyostatni) 1 =
	{if}
		1 (S.L.6000p_jazda)
		1 (S.L.6000p_jazdazrj)
		0 (S.L.BylOdjazd)
		1 (S.L.6000p_wkursu_nrprzystanku)
		"6kP\6000p_e_jazda.dds" (S.$.6000p_ekran)
		(M.V.GetTTLineString) (S.$.Matrix_Nr) $StrToFloat 100 * (S.L.IBIS_Linie_Complex) (M.V.GetRouteIndex) (S.L.IBIS_RouteIndex)
		(M.V.GetTTLineString) (S.$.Matrix_Nr)
		(M.V.GetTTTerminusIndex) (S.L.IBIS_TerminusIndex) 
		(M.L.IBIS_RefreshBusstop)
		(T.L.6000p_piep)
	{endif}		
	(L.L.6000p_wkursu_nrprzystanku) (M.V.GetTTBusstopCount) <
	{if}
		(L.L.6000p_wkursu_nrprzystanku) 1 + (S.L.6000p_wkursu_nrprzystanku_temp)
		2 (S.L.6000p_jazda)
		"6kP\6000p_e_jazda_korekta.dds" (S.$.6000p_ekran)	
		(T.L.6000p_piep)
	{endif}
{endif}
{end}


{trigger:6000p_rozpoczeto}
(L.L.BylOdjazd) 1 =
{if}
	0 (S.L.6000p_rozpoczeto)
	(T.L.6000p_piep)
{endif}
{end}

{trigger:6000p_ostatni}
(L.L.6000p_ostatni) 1 =
{if}
	1 (S.L.6000p_jazda)
	1 (S.L.6000p_jazdazrj)
	0 (S.L.BylOdjazd)
	1 (S.L.6000p_wkursu_nrprzystanku)
	"6kP\6000p_e_jazda.dds" (S.$.6000p_ekran)
	(M.V.GetTTLineString) (S.$.Matrix_Nr) $StrToFloat 100 * (S.L.IBIS_Linie_Complex) (M.V.GetRouteIndex) (S.L.IBIS_RouteIndex)
	(M.V.GetTTLineString) (S.$.Matrix_Nr)
	(M.V.GetTTTerminusIndex) (S.L.IBIS_TerminusIndex) 
	(M.L.IBIS_RefreshBusstop)	
	0 (S.L.6000p_ostatni)
	(T.L.6000p_piep)
{endif}
{end}

{macro:blokada_kasownikow}
	"..\..\Announcements\" 0 (M.V.GetDepotStringGlobal) "\" $+ $+ "Komunikat_Blokada" $+ $msg ".wav" $+
	(T.F.ev_IBIS_Ansagen)
{end}


{macro:AktualnyPrzystanekZapowiedz}
	(L.L.IBIS_RouteIndex) (M.V.GetBusstopCount) 1 - (L.L.IBIS_busstop) <=
	{if}
		-1 (S.L.IBIS_RouteIndex)					
	{endif}	
	(L.L.6000p_wkursu_nrprzystanku) 0 >
	{if}

		"..\..\Announcements\" 0 (M.V.GetDepotStringGlobal) "\" $+ $+ (L.L.6000p_wkursu_nrprzystanku) 1 - (M.V.GetTTBusstopName) $+ $msg

		(M.V.GetTTBusstopCount) (L.L.6000p_wkursu_nrprzystanku) <=
		{if}
			"_#terminus" $+
		{endif}

		"_.wav" $+
		(T.F.ev_IBIS_Ansagen)
	{endif}
{end}

{macro:NastepnyPrzystanekZapowiedz}
	(L.L.6000p_wkursu_nrprzystanku) 1 >
	{if}

		"..\..\Announcements\" 0 (M.V.GetDepotStringGlobal) "\" $+ $+ (L.L.6000p_wkursu_nrprzystanku) 1 - (M.V.GetTTBusstopName) $+ $msg

		".wav" $+
		(T.F.ev_IBIS_Ansagen)
	{endif}
{end}

{macro:IBIS_RefreshBusstop}

	(L.L.IBIS_RouteIndex) 0 <
	{if}
		"" (S.$.act_busstop)
	{else}
	(L.L.IBIS_RouteIndex) (M.V.GetBusstopCount) (L.L.IBIS_busstop) <=
	{if}
'Wenn der Bushaltestellenindex gr  er oder gleich der Anzahl ist und somit zu gro  (der Bushaltestellenindex ist wie alle Indizes nullbasiert), 	
'dann wechsele automatisch auf die Gegenroute, sofern der Index 01 oder 02 ist und der jeweilige andere Index existiert. Sonst belasse die Route.
		0 (S.L.IBIS_busstop)
' Entwerter umstellen:
		(T.L.ev_IBIS_entwerter)
		(L.L.IBIS_busstop_entwerter_soll) (S.L.IBIS_busstop_entwerter_ist)



'Suche den Routeindex:

		(L.L.IBIS_LinieKurs) 100 * l6 + (M.V.GetRouteIndex) s1
		0 >=
		{if}
'Wenn g ltig, dann wechsele:
			l6 (S.L.IBIS_Route)
'(M.L.Fahrscheindrucker-Haltestelle)
		{endif}
	{else}
		0 (S.L.IBIS_mode)
	{endif}
	{endif}

'Setzen der String-Variable "act_busstop" f r die OMSI-interne Berechnung und daraus Ableitung des "globalen" Haltestellenindexes:

	(L.L.IBIS_RouteIndex) (L.L.IBIS_busstop) (M.V.GetRouteBusstopIdent) (S.$.act_busstop)
	(M.V.GetBusstopIndex) (S.L.IBIS_busstop_index)


'Sonst zeige die Bushaltestelle
	(L.L.IBIS_busstop_index) 3 (M.V.GetBusstopString)
	(S.$.IBIS_busstop_name)

'Ausrechnen der neuen Entwerterposition:
	(L.L.IBIS_busstop_offset) (L.L.IBIS_busstop) + (S.L.IBIS_busstop_entwerter_soll)

{end}

{macro:brygadowka}
	(L.L.6000p_jazda) 1 =
	(L.L.6000p_jazda) 2 = ||
	{if}
		(L.$.6000p_nrBryg) (S.$.RG_brygadowka)
	{else}
		"" (S.$.RG_brygadowka)
	{endif}
{end}

