'----------------------
'	Trigger
'----------------------

'####################################
'### Toggle Mirrortype
'####################################

{trigger:toggle_Mirror}
	(L.L.Mirrortype_int) 1 + (S.L.Mirrortype_int)
	(L.L.Mirrortype_int) 3 =
	{if}
		0 (S.L.Mirrortype_int)
	{endif}
	(T.L.ev_VDV_on)
{end}

'####################################
'### Toggle Cashdesk
'####################################

{trigger:toggle_cashdesk}

	(L.L.cashdesk_EUR) ! (S.L.cashdesk_EUR)
	(T.L.ev_licht_dreh)
{end}


'####################################
'### Toggle Dachaufbauten
'####################################

{trigger:toggle_Fahrerklima}

	(L.L.Klima_klein_vorn_int) ! (S.L.Klima_klein_vorn_int)
	(T.L.ev_licht_dreh)
{end}

{trigger:toggle_Klima_gross_vorn}

	(L.L.Klima_Gross_vorn_int) ! (S.L.Klima_Gross_vorn_int)
	(T.L.ev_licht_dreh)
{end}


{trigger:toggle_Klima_gross_hinten}

	(L.L.Klima_Gross_hinten_int) ! (S.L.Klima_Gross_hinten_int)
	(T.L.ev_licht_dreh)
{end}


{trigger:toggle_Dachantenne}

	(L.L.Antennen_Dach_int) ! (S.L.Antennen_Dach_int)
	(T.L.ev_licht_dreh)
{end}

'####################################
'### Toggle Trennstange Tür 1
'####################################

{trigger:toggle_Trennstange_Tuer_1}

	(L.L.Trennstange_Tuer_1_int) ! (S.L.Trennstange_Tuer_1_int)
	(T.L.ev_licht_dreh)
{end}

'####################################
'### Zusatzschalter - Sideboard
'####################################

'####################################
'### Tuer 2 Auto on/off
'####################################

{trigger:toggle_auto_door2}

	(L.L.bremse_feststell_sw)
	(L.L.Leuchtmelder_5) ! &&
	(L.L.door_2) 0 = &&
	(L.L.door_3) 0 = &&
	{if}
		(L.L.auto_door2_anim) ! (S.L.auto_door2_anim)
		(L.L.auto_door2_anim) 1 =
		{if}
			(T.L.ev_VDV_on)
			1 (S.L.auto_door2_int)
		{else}
			(T.L.ev_VDV_off)
			0 (S.L.auto_door2_int)
			0 (S.L.door2_bremse_halte_sw)
		{endif}
	{endif}
{end}

'####################################
'### Tuer Piep on/off
'####################################

{trigger:toggle_doorwarn}

	(L.L.doorwarn_anim) ! (S.L.doorwarn_anim)
	(L.L.doorwarn_anim) 1 =
	{if}
		(T.L.ev_VDV_on)
		1 (S.L.vis_doorwarn_int)
	{else}
		(T.L.ev_VDV_off)
		0 (S.L.vis_doorwarn_int)
	{endif}
{end}

'####################################
'### Door Blink Button on/off
'####################################

{trigger:toggle_Door_blink_Buttons}

	(L.L.Door_blink_Buttons_anim) ! (S.L.Door_blink_Buttons_anim)
	(L.L.Door_blink_Buttons_anim) 1 =
	{if}
		(T.L.ev_VDV_on)
		1 (S.L.Door_blink_Buttons_int)
	{else}
		(T.L.ev_VDV_off)
		0 (S.L.Door_blink_Buttons_int)
	{endif}
{end}

'####################################
'### Door leaf lock
'####################################

{trigger:Door_leaf_lock_0}

(L.L.has_no_Door_Wing_lock) !
{if}
	(L.L.Door_leaf_lock_anim_up)
	(L.L.Door_leaf_lock_anim_dn) ||
	{if}
		0 (S.L.Door_leaf_lock_anim_up) (S.L.Door_leaf_lock_anim_dn)
		(T.L.ev_VDV_toggle_off)
	{else}
		(L.L.Door_leaf_lock_anim_up) ! (S.L.Door_leaf_lock_anim_up)
		{if}
			(T.L.ev_VDV_toggle_on)
		{else}
			(T.L.ev_VDV_toggle_off)
		{endif}
	{endif}
{endif}
{end}

{trigger:Door_leaf_lock_1}

(L.L.has_no_Door_Wing_lock) !
{if}
	(L.L.Door_leaf_lock_anim_up)
	(L.L.Door_leaf_lock_anim_dn) ||
	{if}
		0 (S.L.Door_leaf_lock_anim_up) (S.L.Door_leaf_lock_anim_dn)
		(T.L.ev_VDV_toggle_off)
	{else}
		(L.L.Door_leaf_lock_anim_dn) ! (S.L.Door_leaf_lock_anim_dn)
		{if}
			(T.L.ev_VDV_toggle_on)
		{else}
			(T.L.ev_VDV_toggle_off)
		{endif}
	{endif}
{endif}
{end}

{trigger:toggle_Door_leaf_lock}

(L.L.has_no_Door_Wing_lock) !
{if}
	(L.L.tuersperre2) 1 + (S.L.tuersperre2)
	
	(L.L.tuersperre2) 0 =
	{if}
		0 (S.L.tuersperre2) (S.L.Door_leaf_lock_anim_up) (S.L.Door_leaf_lock_anim_dn) (S.L.tuersperre)
		(T.L.ev_VDV_toggle_off)
	{endif}
	
	(L.L.tuersperre2) 1 =
	{if}
		(L.L.door_0) 0 =
		(L.L.door_1) 0 = &&
		{if}

'### Türflügel 0 gesperrt

			-1 (S.L.tuersperre)
			1 (S.L.Door_leaf_lock_anim_up)
			0 (S.L.Door_leaf_lock_anim_dn)
			(T.L.ev_VDV_toggle_on)
		{endif}
	{endif}	
	
	(L.L.tuersperre2) 2 =
	{if}
		(L.L.door_0) 0 =
		(L.L.door_1) 0 = &&
		{if}
			0 (S.L.Door_leaf_lock_anim_up) (S.L.Door_leaf_lock_anim_dn) (S.L.tuersperre)
			(T.L.ev_VDV_toggle_off)
		{endif}
	{endif}	
	
	(L.L.tuersperre2) 3 =
	{if}
		(L.L.door_0) 0 =
		(L.L.door_1) 0 = &&
		{if}

'### Türflügel 1 gesperrt

			1 (S.L.tuersperre) (S.L.Door_leaf_lock_anim_dn)
			0 (S.L.Door_leaf_lock_anim_up)
			(T.L.ev_VDV_toggle_on)
		{endif}
	{endif}	
	
	(L.L.tuersperre2) 4 =
	{if}
		(L.L.door_0) 0 =
		(L.L.door_1) 0 = &&
		{if}
			0 (S.L.tuersperre2) (S.L.Door_leaf_lock_anim_up) (S.L.Door_leaf_lock_anim_dn) (S.L.tuersperre)
			(T.L.ev_VDV_toggle_off)
		{endif}
	{endif}	
	
{endif}

{end}

'####################################
'### Autokneeling on/off
'####################################

{trigger:toggle_auto_kneeling}

	(L.L.enable_auto_kneeling_int) ! (S.L.enable_auto_kneeling_int)
	{if}
		(T.L.ev_VDV_on)
	{else}
		(T.L.ev_VDV_off)
	{endif}
{end}

'####################################

'----------------------
'	INIT
'----------------------


{macro:DD_misc_init}

	0 (S.L.DD_misc_counter)
{end}

'########################################################################

'----------------------
'	FRAME
'----------------------


{macro:DD_misc_frame}


'#################################################
'#################################################
'###
'### Hier alles drunter, was keinen Strom braucht
'###
'#################################################
'#################################################

'####################################
'### CTI's laden
'####################################

(L.L.DD_misc_counter) 2 <
{if}


'#################################################
'### Spiegelsteuerung
'#################################################


	(L.L.vis_doortype_v) 0 =
	{if}
		(L.L.Mirrortype) (S.L.Mirrortype_int)
	{else}
		99 (S.L.Mirrortype_int)
	{endif}

'#################################################

		(L.L.doorwarn_off) ! (S.L.vis_doorwarn_int)
		(L.L.VDV_ready_off) ! (S.L.VDV_ready_off_int)
		(L.L.auto_door2) (S.L.auto_door2_int)
		(L.L.Door_blink_Buttons) (S.L.Door_blink_Buttons_int)
		(L.L.Klima_Gross_vorn) (S.L.Klima_Gross_vorn_int)
		(L.L.Klima_klein_vorn) (S.L.Klima_klein_vorn_int)
		(L.L.Klima_Gross_hinten) (S.L.Klima_Gross_hinten_int)
		(L.L.Antennen_Dach) (S.L.Antennen_Dach_int)
		(L.L.Trennstange_Tuer_1) (S.L.Trennstange_Tuer_1_int)
		(L.L.enable_auto_kneeling) (S.L.enable_auto_kneeling_int)

		(L.L.DD_misc_counter) 1 + (S.L.DD_misc_counter)
{endif}

'####################################
'### KI-Inneraumbeleuchtung
'####################################

	(L.L.KI-Mode)
	(L.L.lights_stand) &&
	{if}
		1 (S.L.cp_licht_unterdeck_sw) (S.L.KI-Licht)
	{else}
		0 (S.L.cp_licht_unterdeck_sw) (S.L.KI-Licht)
	{endif}

'####################################
'### Zusatzschalter - Sideboard
'####################################

	(L.L.auto_door2_int)
	{if}
		1 (S.L.auto_door2_anim)
	{else}
		0 (S.L.auto_door2_anim)
	{endif}

	(L.L.vis_doorwarn_int)
	{if}
		1 (S.L.doorwarn_anim)
	{else}
		0 (S.L.doorwarn_anim)
	{endif}

	(L.L.Door_blink_Buttons_int)
	{if}
		1 (S.L.Door_blink_Buttons_anim)
	{else}
		0 (S.L.Door_blink_Buttons_anim)
	{endif}

'####################################
'### Toggle Cashdesk
'####################################

	(L.L.cashdesk_EUR)
	{if}
    	"DD-Mod\V3D\cash_levers.dds" (S.$.DD-Kasse)
		"DD-Mod\Geldschein.dds" (S.$.Geldschein_texture)
	{else}
		"DD-Mod\V3D\cash_levers_Eur.dds" (S.$.DD-Kasse)
		"DD-Mod\Geldschein_EUR.dds" (S.$.Geldschein_texture)
	{endif}


'#################################################
'#################################################
'###
'### Hier alles drunter, was Strom braucht
'###
'#################################################
'#################################################


(L.L.elec_busbar_main) 0 >
(L.L.KI-Mode) ! &&
{if}

'####################################
'### Door leaf lock
'####################################

	(L.L.has_no_Door_Wing_lock) !
	{if}
		(L.L.Door_leaf_lock_anim_up) 1 =
		(L.L.tuersperre2) 1 = ||
		{if}
			(L.L.door_0) 0 =
			(L.L.door_1) 0 = &&
			{if}

'### Türflügel 0 gesperrt

				-1 (S.L.tuersperre)
			{endif}
		{endif}

'####################################

		(L.L.Door_leaf_lock_anim_dn) 1 =
		{if}
			(L.L.door_0) 0 =
			(L.L.door_1) 0 = &&
			{if}

'### Türflügel 1 gesperrt

				1 (S.L.tuersperre)
			{endif}
		{endif}

'####################################

		(L.L.Door_leaf_lock_anim_up) !
		(L.L.Door_leaf_lock_anim_dn) ! &&
		(L.L.door_0) 0 = &&
		(L.L.door_1) 0 = &&
		{if}
			0 (S.L.tuersperre)
		{endif}

	{endif}

'####################################

	(L.L.has_no_Door_Wing_lock)
	{if}
		0 (S.L.tuersperre)
	{endif}

'####################################

'####################################
'### Beleuchtung toggle_doorwarn
'####################################

	(L.L.vis_doorwarn_int) 1 =
	{if}
		1 (S.L.doorwarn_control)
	{else}
		0 (S.L.doorwarn_control)
	{endif}

'####################################
'### Beleuchtung toggle_auto_door2
'####################################

	(L.L.auto_door2_int) 1 =
	{if}
		1 (S.L.auto_door2_control)
	{else}
		0 (S.L.auto_door2_control)
	{endif}

'####################################
'### Beleuchtung toggle_Door_blink_Buttons
'####################################

	(L.L.Door_blink_Buttons_int)
	{if}
		1 (S.L.Door_blink_Buttons_control)
	{else}
		0 (S.L.Door_blink_Buttons_control)
	{endif}

'############################################
'### PingPong
'############################################

'### focus04 Edit
'### Script entlasten, Timer muss nicht immer abgefragt werden wenn kein Haltewunsch besteht ;)

'Blinken Türtaster

	(L.L.haltewunschlampe_all)
	(L.L.Door_blink_Buttons_control) &&
	{if}
		(L.L.door_taste_blinken_timer) (L.S.Timegap) + 1 min (S.L.door_taste_blinken_timer)
		0.5 <
		{if}
			1 (S.L.door_taste_blinken)
		{else}
			0 (S.L.door_taste_blinken)
		{endif}
			
		(L.L.door_taste_blinken_timer) 1 =
		{if}
			0 (S.L.door_taste_blinken_timer)

			(L.L.haltewunsch_01)
			{if}
				0 (S.L.door_light_1)
			{endif}

			(L.L.haltewunsch_23)
			{if}
				0 (S.L.door_light_2)
			{endif}

			(L.L.haltewunsch_45)
			{if}
				0 (S.L.door_light_3)
			{endif}
		{endif}

		(L.L.door_taste_blinken)
		{if}
			(L.L.haltewunsch_01)
			{if}
				1 (S.L.door_light_1)
			{endif}

			(L.L.haltewunsch_23)
			{if}
				1 (S.L.door_light_2)
			{endif}

			(L.L.haltewunsch_45)
			{if}
				1 (S.L.door_light_3)
			{endif}
		{endif}
	{endif}

'### focus04 Edit Ende

'############################################
'### PingPong Ende
'############################################

{endif}

'############################################
'### Autokneeling
'############################################

	(L.L.enable_auto_kneeling_int)
	{if}
		1 (S.L.cp_dummy_sw03)
	{else}
		0 (S.L.cp_dummy_sw03)
	{endif}
	
{end}