'##############
'Cockpit-Script
'##############

'Simuliert alle unmittelbar mit dem Armaturenbrett zusammenhängenden Funktionen

'(c) 23.10.2009 Rüdiger Hülsmann
'(c) 03.11.2012 Marcel Kuhnt
'(c) 27.02.2011 Markus Rabe

'Script Version: 1.0
'Omsi release: 1.0

'Needs:
'- antrieb
'- engine
'- bremse
'- lights
'- wiper?
'- doors
'- doors

'NrSpecRandom Seed Area:
'350...355

'Revision History:
'- Rüdiger Hülsmann	09.06.2009	Last Change				
'- Marcel Kuhnt		13.06.2009	Added Gearbox switches			
'- Marcel Kuhnt		13.06.2009	Moved some switchvars to other scripts	
'- Rüdiger Hülsmann	19.06.2009	Added Openable Window Triggers
'- Rüdiger Hülsmann	23.10.2009	Added Battery and kinderwagen light
'- Marcel Kuhnt		26.10.2009	Radio switchable with Motorkühlung (replaced with cassette player)
'- Rüdiger Hülsmann	28.10.2009	Added driver door
'- Rüdiger Hülsmann	16.12.2009	Added driver curtain
'- Rüdiger Hülsmann	18.12.2009	Bugfix driver curtain
'- Marcel Kuhnt		15.04.2010	Traegheit debugged
'- Rüdiger Hülsmann	13.05.2010	Engine temperature
'- Rüdiger Hülsmann	03.06.2010	Automatic battery switch on key insertion (For standard-II-buses)
'- Rüdiger Hülsmann	08.06.2010	Automatic battery switch made optional, Auxiliary heating switchable by button or switch
'- Rüdiger Hülsmann	23.06.2010	Added mouse-clickable wiper lever on wheel console
'- Rüdiger Hülsmann	08.07.2010	Wiper lever: Improved usability 
'- Rüdiger Hülsmann	18.07.2010	Wiper lever: soundfix for keyboard operation and new ignition key algorithm 
'- Rüdiger Hülsmann	16.09.2010	Auxheat Switch Bugfix
'- Rüdiger Hülsmann	18.09.2010	Imported microphone switch
'- Rüdiger Hülsmann	17.10.2010	Added pressure warning needle
'- Rüdiger Hülsmann	23.10.2010	Added old-style gear button functionality
'- Rüdiger Hülsmann	06.11.2010	Gear-button "1" functionality removed for old-style gear buttons
'- Rüdiger Hülsmann	16.11.2010	Heating sliders
'- Rüdiger Hülsmann	23.11.2010	Central lubrication, cabin heater sound
'- Rüdiger Hülsmann	23.12.2010	Included 10 "multi-purpose" dummy switches
'- Rüdiger Hülsmann	29.12.2010	ASR switch
'- Rüdiger Hülsmann	04.01.2011	"D-only" gear selector function
'- Rüdiger Hülsmann	05.01.2011	fog lamp switch, high beam lever animation, clock debugged
'- Rüdiger Hülsmann	07.01.2011	Wiper lever sound and function debugges, availybility of several cockpit functions depending on bus type (via constfile)
'- Rüdiger Hülsmann	16.01.2011	Support for wiper turn-switch
'- Rüdiger Hülsmann	18.01.2011	Old-style gear button sounds
'- Rüdiger Hülsmann	26.01.2011	Invertable driver door
'- Rüdiger Hülsmann	26.01.2011	Thermometer
'- Markus Rabe		27.02.2011	Heizlüfter und Wagenheizung Motorabhängig, Leuchtmelder Hintertür an 80er D Wagen angepasst
'- Marcel Kuhnt		25.06.2011	Nebelscheinwerfer-Schalter (cp_licht_nebelschw_sw)
'- Marcel Kuhnt		29.06.2011	Türkontrolle für D92 und D86 integriert
'- Marcel Kuhnt		22.06.2012	Uhr läuft nur, wenn Strom vorhanden
'- Marcel Kuhnt		09.07.2012	Busbar wird als Faktor/Spannung interpretiert
'- Marcel Kuhnt		25.07.2012	Stromverbrauch, Generierung von Leitwert
'- Marcel Kuhnt		01.11.2012	Türentriegelungs-Leuchtmelder
'- Marcel Kuhnt		02.11.2012	Türentriegelungs-Leuchtmelder für drei Türen
'- Marcel Kuhnt		03.11.2012	Andere Klappfensterbezeichnungen und nur vier Stück
'- Marcel Kuhnt		04.11.2012	Zweite Türkontrolle
'- Marcel Kuhnt		22.03.2013	Hinzugefügt: Schalter Hublift & Knickschutz-Override
'- Marcel Kuhnt		11.09.2013	Dachluken
'- Marcel Kuhnt		12.09.2013	Added Fahrgastpendel
'- Marcel Kuhnt		13.09.2013	Zwei Fahrgastpendel, die zufällige physikalische Eigenschaften haben
'- Marcel Kuhnt		14.10.2013	Neues Heizgerät für NL/NG eingebaut, Klimator- und Wagenlüfter werden im Heizungs-Script simuliert
'- Rüdiger Hülsmann	26.10.2013	Kneeling-Funktion
'- Marcel Kuhnt		08.11.2013	Hublift-Masterschalter


'------------------------------------------------------------------------------------------


'----------------------
'	Trigger
'----------------------

{trigger:cp_klimator_sw_drag}
	(L.S.mouse_X) 100 / (L.L.cp_klimator_sw) + (S.L.cp_klimator_sw) s0
	l0 0 <
	{if}
		0 (S.L.cp_klimator_sw)
	{endif}
	l0 1 >
	{if}
		1 (S.L.cp_klimator_sw)
	{endif}
{end}

{trigger:cp_zahltisch_hebel_drag}
	(L.S.mouse_x) -100 / (L.L.zahltisch_hebel) + (S.L.zahltisch_hebel)
{end}

{trigger:cp_zahltisch_drag}
	(L.S.mouse_x) -100 / (L.L.zahltisch) + abs 0 max 2 min /-/ (S.L.zahltisch)
{end}

{trigger:cp_heizregler_fussraum_drag}
	(L.S.mouse_y) -150 / (L.L.cockpit_heizregler_fussraum) + 0 max 1 min (S.L.cockpit_heizregler_fussraum)
{end}

{trigger:cp_heizregler_temp_drag}
	(L.S.mouse_y) -150 / (L.L.cockpit_heizregler_temp) + 0 max 1 min (S.L.cockpit_heizregler_temp)
{end}

{trigger:cp_heizregler_umluft_drag}
	(L.S.mouse_y) -150 / (L.L.cockpit_heizregler_umluft) + 0 max 1 min (S.L.cockpit_heizregler_umluft) s0

'	Stufen:
'	0: Umluftheizung
'	1: Direktbelüftung
'	2: Frischluftheizung

	l0 0.2 <
	{if}
		0 (S.L.cockpit_heizregler_ventilation_mode)
	{else}
		l0 0.8 <
		{if}
			1 (S.L.cockpit_heizregler_ventilation_mode)
		{else}
			2 (S.L.cockpit_heizregler_ventilation_mode)
		{endif}
	{endif}

{trigger:horn}
	
		(L.L.cockpit_hupe) ! (L.L.elec_busbar_main) (C.L.elec_busbar_minV) > &&
		{if}
			(T.L.ev_hupe_an)
		{endif}
		1 (S.L.cockpit_hupe)
{end}

{trigger:horn_off}	
	
		(L.L.cockpit_hupe) (L.L.elec_busbar_main) (C.L.elec_busbar_minV) > &&
		{if}
			(T.L.ev_hupe_aus)
		{endif}
		0 (S.L.cockpit_hupe)	
{end}

{trigger:cp_retarder_direkt_toggle}
	(L.L.cp_retarder_sw_direkt) ! (S.L.cp_retarder_sw_direkt) s1
	1 =
	{if}
		(T.L.ev_VDV_on)
	{else}
		(T.L.ev_VDV_off)
	{endif}
{end}

{trigger:cp_retarder_toggle}
	(L.L.cp_retarder_sw) ! (S.L.cp_retarder_sw) s1
	1 =
	{if}
		(T.L.ev_VDV_on)
	{else}
		(T.L.ev_VDV_off)
	{endif}
{end}

{trigger:cp_motorkuehlung_toggle}
	(C.L.cockpit_has_coolingswitch)
	{if}
		(L.L.cp_motorkuehlung_sw) ! (S.L.cp_motorkuehlung_sw) s1
		1 =
		{if}
			(T.L.ev_VDV_on)
		{else}
			(T.L.ev_VDV_off)
		{endif}
	{endif}
{end}

{trigger:cp_licht_nebelschw_sw}
	(L.L.cp_licht_nebelschw_sw) 
	{if}
		0 (S.L.cp_licht_nebelschw_sw) s1
	{else}
		1 (S.L.cp_licht_nebelschw_sw) s1
	{endif}		
	1 =
	{if}
		(T.L.ev_VDV_on)
	{else}
		(T.L.ev_VDV_off)
	{endif}
{end}

{trigger:cp_wischer_schnell_toggle}
	(L.L.cp_wischer_schnell_sw) ! (S.L.cp_wischer_schnell_sw) s1
	1 =
	{if}
		(T.L.ev_VDV_on)
	{else}
		(T.L.ev_VDV_off)
	{endif}
{end}

{trigger:kw_wipermode_up}
	(L.L.cp_wischer_einaus_sw) ! (S.L.cp_wischer_einaus_sw) s1
	{if}
		2 (S.L.cockpit_wischerhebel_mode) (S.L.cockpit_wischer_drehschalter_mode)
		2 3 / (S.L.cockpit_wischerhebel) (S.L.cockpit_wischer_drehschalter)
		(L.L.cp_wischer_intervall_sw) !
		{if}
			(T.L.ev_wischerhebel)
		{endif}
	{else}
		(L.L.cp_wischer_intervall_sw)
		{if}
			1 (S.L.cockpit_wischerhebel_mode) (S.L.cockpit_wischer_drehschalter_mode)
			1 3 / (S.L.cockpit_wischerhebel) 
			0 (S.L.cockpit_wischer_drehschalter)
		{else}
			0 (S.L.cockpit_wischerhebel_mode) (S.L.cockpit_wischer_drehschalter_mode) (S.L.cockpit_wischerhebel) 
			1 3 / (S.L.cockpit_wischer_drehschalter)
			(T.L.ev_wischerhebel)
		{endif}
	{endif}
	(C.L.wiper_lever) !
	{if}
		l1
		1 =
		{if}
			(T.L.ev_VDV_on)
		{else}
			(T.L.ev_VDV_off)
		{endif}
	{endif}
{end}

{trigger:cp_wischer_intervall_toggle}
	(L.L.cp_wischer_intervall_sw) ! (S.L.cp_wischer_intervall_sw) s1
	(L.L.cp_wischer_einaus_sw) ! &&
	{if}
		1 (S.L.cockpit_wischerhebel_mode) (S.L.cockpit_wischer_drehschalter_mode)
		1 3 / (S.L.cockpit_wischerhebel) 
		0 (S.L.cockpit_wischer_drehschalter)
	{else}
		(L.L.cp_wischer_einaus_sw)
		{if}
			2 (S.L.cockpit_wischerhebel_mode) (S.L.cockpit_wischer_drehschalter_mode)
			2 3 / (S.L.cockpit_wischerhebel) (S.L.cockpit_wischer_drehschalter)
		{else}
			0 (S.L.cockpit_wischerhebel_mode) (S.L.cockpit_wischer_drehschalter_mode) (S.L.cockpit_wischerhebel)
			1 3 / (S.L.cockpit_wischer_drehschalter)
		{endif}

	{endif}
	(C.L.wiper_lever) !
	{if}
		l1
		1 =
		{if}
			(T.L.ev_VDV_on)
		{else}
			(T.L.ev_VDV_off)
		{endif}
	{endif}
{end}

{trigger:cp_wischer_wascher_button}
	1 (S.L.cp_wischer_wascher_sw) s1
	(C.L.wiper_lever)
	{if}
		(T.L.ev_wischerhebel)
		1 (S.L.cockpit_wischerhebel_x)
	{else}
		l1
		1 =
		{if}
			(T.L.ev_VDV_on)
		{else}
			(T.L.ev_VDV_off)
		{endif}
	{endif}
{end}

{trigger:cp_wischer_wascher_button_off}
	0 (S.L.cp_wischer_wascher_sw) s1
	(S.L.wiper_wascher_sw)
	(C.L.wiper_lever)
	{if}
		(T.L.ev_wischerhebel)
		0 (S.L.cockpit_wischerhebel_x)
	{else}
		l1
		1 =
		{if}
			(T.L.ev_VDV_on)
		{else}
			(T.L.ev_VDV_off)
		{endif}
	{endif}
{end}

{trigger:cp_heizluefter_toggle}
	(L.L.cp_heizluefter_sw) ! (S.L.cp_heizluefter_sw) s1
	1 =
	{if}
		(T.L.ev_VDV_on)
	{else}
		(T.L.ev_VDV_off)
	{endif}
{end}

{trigger:cp_spiegelheizung_toggle}
	(L.L.cp_spiegelheizung_sw) ! (S.L.cp_spiegelheizung_sw) s1
	1 =
	{if}
		(T.L.ev_VDV_on)
	{else}
		(T.L.ev_VDV_off)
	{endif}
{end}

{trigger:cp_autokneel_toggle}
	(L.L.cp_autokneel_sw) ! (S.L.cp_autokneel_sw)
	{if}
		(T.L.ev_VDV_on)
	{else}
		(T.L.ev_VDV_off)
	{endif}
{end}

{trigger:cp_notheben}
	1 (S.L.cp_notheben_anim)
	1 (S.L.notheben_armed)
	(T.L.ev_VDV_toggle_on)
{end}

{trigger:cp_notheben_off}
	0 (S.L.cp_notheben_anim)
	(T.L.ev_VDV_toggle_off)
{end}

{trigger:cp_kneeling_toggle}
	(L.L.kneeling_armed) ! (S.L.kneeling_armed)
	(T.L.ev_VDV_toggle_on)
	1 (S.L.kneeling_anim)
{end}

{trigger:cp_kneeling_toggle_off}
	(T.L.ev_VDV_toggle_off)
	0 (S.L.kneeling_anim)
{end}

{trigger:cp_dimm_up}
	1 (S.L.dimm_up_anim)
	(L.L.elec_busbar_main)
	{if}
		(L.L.vdv_dim_mode) 1 - (S.L.vdv_dim_mode)
		(L.L.vdv_dim_mode) !
		{if}
			4 (S.L.vdv_dim_mode)
		{endif}
	{endif}
	(T.L.ev_VDV_toggle_on)
{end}

{trigger:cp_dimm_up_off}
	0 (S.L.dimm_up_anim)
	(T.L.ev_VDV_toggle_off)
{end}

{trigger:cp_dimm_down}
	1 (S.L.dimm_down_anim)
	(L.L.elec_busbar_main)
	{if}
		(L.L.vdv_dim_mode) 1 + (S.L.vdv_dim_mode)
		(L.L.vdv_dim_mode) 4 >
		{if}
			1 (S.L.vdv_dim_mode)
		{endif}
	{endif}
	(T.L.ev_VDV_toggle_on)
{end}

{trigger:cp_dimm_down_off}
	0 (S.L.dimm_down_anim)
	(T.L.ev_VDV_toggle_off)
{end}


{trigger:cp_display_dim}

	(L.L.vdv_dim_mode) 1 + (S.L.vdv_dim_mode)

	(L.L.vdv_dim_mode) 4 >
	{if}
		1 (S.L.vdv_dim_mode)
	{endif}

	1 (S.L.display_dim_sw) s1
	1 =
	{if}
		(T.L.ev_VDV_toggle_on)
	{else}
		(T.L.ev_VDV_toggle_off)
	{endif}
{end}

{trigger:cp_display_dim_off}

	0 (S.L.display_dim_sw) s1
	1 =
	{if}
		(T.L.ev_VDV_toggle_on)
	{else}
		(T.L.ev_VDV_toggle_off)
	{endif}
{end}
'--------------------------------------------------------
'Dummys:

{trigger:cp_dummy_sw01}

	1 (S.L.dummy_sw01_anim)
	
	(L.L.cp_dummy_sw01) ! (S.L.cp_dummy_sw01) s1
	1 =
	{if}
		(T.L.ev_VDV_on)
	{else}
		(T.L.ev_VDV_off)
	{endif}
{end}

{trigger:cp_dummy_sw01_off}

	0 (S.L.dummy_sw01_anim)
	
{end}

{trigger:cp_dummy_sw02_toggle}
	(L.L.cp_dummy_sw02) ! (S.L.cp_dummy_sw02) s1
	1 =
	{if}
		(T.L.ev_VDV_on)
	{else}
		(T.L.ev_VDV_off)
	{endif}
{end}

{trigger:cp_dummy_sw03_toggle}
	(L.L.cp_dummy_sw03) ! (S.L.cp_dummy_sw03) s1
	1 =
	{if}
		(T.L.ev_VDV_on)
	{else}
		(T.L.ev_VDV_off)
	{endif}
{end}

{trigger:cp_taster_spiegel}
	(L.L.cp_taster_spiegel_sw) ! (S.L.cp_taster_spiegel_sw) s1
	1 =
	{if}
		(T.L.ev_VDV_on)
	{else}
		(T.L.ev_VDV_off)
	{endif}
{end}

{trigger:cp_dummy_sw05_toggle}
	(L.L.cp_dummy_sw05) ! (S.L.cp_dummy_sw05) s1
	1 =
	{if}
		(T.L.ev_VDV_on)
	{else}
		(T.L.ev_VDV_off)
	{endif}
{end}

{trigger:cp_dummy_sw06_toggle}
	(L.L.cp_dummy_sw06) ! (S.L.cp_dummy_sw06) s1
	1 =
	{if}
		(T.L.ev_VDV_on)
	{else}
		(T.L.ev_VDV_off)
	{endif}
{end}

{trigger:cp_dummy_sw07_toggle}
	(L.L.cp_dummy_sw07) ! (S.L.cp_dummy_sw07) s1
	1 =
	{if}
		(T.L.ev_VDV_on)
	{else}
		(T.L.ev_VDV_off)
	{endif}
{end}

{trigger:cp_dummy_sw08_toggle}
	(L.L.cp_dummy_sw08) ! (S.L.cp_dummy_sw08) s1
	1 =
	{if}
		(T.L.ev_VDV_on)
	{else}
		(T.L.ev_VDV_off)
	{endif}
{end}

{trigger:cp_dummy_sw09_toggle}
	(L.L.cp_dummy_sw09) ! (S.L.cp_dummy_sw09) s1
	1 =
	{if}
		(T.L.ev_VDV_on)
	{else}
		(T.L.ev_VDV_off)
	{endif}
{end}

{trigger:cp_dummy_sw10_toggle}
	(L.L.cp_dummy_sw10) ! (S.L.cp_dummy_sw10) s1
	1 =
	{if}
		(T.L.ev_VDV_on)
	{else}
		(T.L.ev_VDV_off)
	{endif}
{end}

{trigger:cp_schalter_ASR_off_toggle}
	(L.L.cp_ASR_off) ! (S.L.cp_ASR_off) s1
	1 =
	{if}
		(T.L.ev_VDV_on)
	{else}
		(T.L.ev_VDV_off)
	{endif}
{end}

{trigger:cp_schalter_hub_dn_toggle_off}
	0 (S.L.cp_hub_dn_sw) s1
	1 =
	{if}
		(T.L.ev_VDV_toggle_on)
	{else}
		(T.L.ev_VDV_toggle_off)
	{endif}
{end}

{trigger:cp_schalter_hub_mstr_toggle}
	(L.L.cp_hub_mstr_sw) ! (S.L.cp_hub_mstr_sw) 0 s1
	1 =
	{if}
		(T.L.ev_VDV_on)
	{else}
		(T.L.ev_VDV_off)
	{endif}
{end}

{trigger:cp_schalter_knick_ovrd_toggle}
	(L.L.cp_knick_ovrd_sw) ! (S.L.cp_knick_ovrd_sw) s1
	1 =
	{if}
		(T.L.ev_VDV_toggle_on)
	{else}
		(T.L.ev_VDV_toggle_off)
	{endif}
{end}

{trigger:cp_rollo_drag}

	(L.L.cp_rollo_pos) (S.L.cp_rollo_lastpos)

	1 (S.L.cp_rollo_dragged)
	0 (S.L.cp_rollo_speed)
	(L.S.mouse_y) 500 / (L.L.cp_rollo_pos) + -1 max 0 min (S.L.cp_rollo_pos)

	(L.L.cp_rollo_pos) (L.L.cp_rollo_lastpos) - abs (L.S.Timegap) / (S.L.cp_rollo_speed)
{end}

{trigger:cp_rollo_off}
	0 (S.L.cp_rollo_dragged)
	(T.L.ev_rollo_end)
{end}

{trigger:cp_rollo2_drag}

	(L.L.cp_rollo2_pos) (S.L.cp_rollo2_lastpos)

	1 (S.L.cp_rollo2_dragged)
	0 (S.L.cp_rollo2_speed)
	(L.S.mouse_y) 500 / (L.L.cp_rollo2_pos) + -1 max 0 min (S.L.cp_rollo2_pos)

	(L.L.cp_rollo2_pos) (L.L.cp_rollo2_lastpos) - abs (L.S.Timegap) / (S.L.cp_rollo2_speed)
{end}

{trigger:cp_rollo2_off}
	0 (S.L.cp_rollo2_dragged)
	(T.L.ev_rollo_end)
{end}

{trigger:cp_fahrerfenster_opn_drag}

	(L.L.cp_fahrerfenster_pos) (S.L.cp_fahrerfenster_lastpos)

	(L.S.mouse_x) -500 / (L.L.cp_fahrerfenster_pos) + (S.L.cp_fahrerfenster_pos) s0
	l0 0 <
	{if}
		0 (S.L.cp_fahrerfenster_pos)
		(L.L.cp_fahrerfenster_endanschlag) !
		{if}
			(T.L.ev_fahrerfenster_cls)
		{endif}
		1 (S.L.cp_fahrerfenster_endanschlag)
		
	{endif}
	l0 1 >
	{if}
		1 (S.L.cp_fahrerfenster_pos)
		(L.L.cp_fahrerfenster_endanschlag) !
		{if}
			(T.L.ev_fahrerfenster_opn)
		{endif}
		1 (S.L.cp_fahrerfenster_endanschlag)
	{endif}

	(L.L.cp_fahrerfenster_pos) s0 0 > l0 1 < &&
	{if}
		0 (S.L.cp_fahrerfenster_endanschlag)
	{endif}
	(L.L.cp_fahrerfenster_pos) (L.L.cp_fahrerfenster_lastpos) - abs (L.S.Timegap) / (S.L.cp_fahrerfenster_speed)
{end}

{trigger:cp_fahrerfenster_opn_off}
	0 (S.L.cp_fahrerfenster_speed)
{end}

{trigger:cp_schluessel_mov_drag}

'	Fallunterscheidung: Schlüssel in x- oder y-Richtung?
	
	(L.S.mouse_x) abs (L.S.mouse_y) abs >=
	{if}

'		Zunächst Translation (Einstecken)

		(L.S.mouse_x) -10 / (L.L.cp_schluessel_trans) + 0 max 1 min (S.L.cp_schluessel_trans) s0
		
'		Stufen:
'		0: Schlüssel abgezogen
'		1: Schlüssel eingesteckt

		l0 0.5 <
		{if}
			0 (S.L.cp_schluessel_trans_mode) (S.L.elec_busbar_main_sw)
		{else} 
			1 (S.L.cp_schluessel_trans_mode)
			1 (S.L.bremse_ABS_selftest)

'			Wenn beim Einstecken bereits der Stromkreis geschlossen werden soll, ohne Trennschalter:

			(C.L.automatic_battery_switch)
			{if}
				1 (S.L.elec_busbar_main_sw)
			{endif}		
		{endif}
	{else}

'		Sonst Rotation (Lichtschalter)

		(L.S.mouse_y) -20 / (L.L.cp_schluessel_rot) + 0 max 1 min (S.L.cp_schluessel_rot) s1

'		Stufen:
'		0: Licht aus
'		1: Standlicht
'		2: Abblendlicht

		l1 0.2 <
		{if}
			0 (S.L.cp_schluessel_rot_mode) 
		{else} 
			l1 0.8 <
			{if}
				1 (S.L.cp_schluessel_rot_mode) 
			{else}
				2 (S.L.cp_schluessel_rot_mode)
			{endif}
		{endif}
	{endif}
{end}

{trigger:cp_schluessel_mov_off}

'	Einrasten auf den festen Positionen:
	(L.L.cp_schluessel_trans_mode) (S.L.cp_schluessel_trans)
	(L.L.cp_schluessel_rot_mode) 2 / (S.L.cp_schluessel_rot)

{end}

{trigger:cp_lenkrad_toggle}
	(L.L.cp_lenkrad_visible) ! (S.L.cp_lenkrad_visible)
{end}

{trigger:cp_klappfenster_1}
	(L.L.vis_clima) !
	(L.L.vis_clima_h) ! && 
	{if}
		(L.L.cp_klappfenster_1) ! (S.L.cp_klappfenster_1) s1
		(M.L.klappfenstersound_1)
	{else}
		0 (S.L.cp_klappfenster_1)
	{endif}
{end}

{trigger:cp_klappfenster_2}
	(L.L.vis_clima) !
	(L.L.vis_clima_h) ! && 
	{if}
		(L.L.cp_klappfenster_2) ! (S.L.cp_klappfenster_2) s1
		(M.L.klappfenstersound_2)
	{else}
		0 (S.L.cp_klappfenster_4)
	{endif}
{end}

{trigger:cp_klappfenster_3}
	(L.L.vis_clima) !
	(L.L.vis_clima_h) ! && 
	{if}
		(L.L.cp_klappfenster_3) ! (S.L.cp_klappfenster_3) s1
		(M.L.klappfenstersound_T1)
	{else}
		0 (S.L.cp_klappfenster_4)
	{endif}
{end}

{trigger:cp_klappfenster_4}
	(L.L.vis_clima) !
	(L.L.vis_clima_h) ! && 
	{if}
		(L.L.cp_klappfenster_4) ! (S.L.cp_klappfenster_4) s1
		(M.L.klappfenstersound_T2)
	{else}
		0 (S.L.cp_klappfenster_4)
	{endif}
{end}

{trigger:cp_Fahrertuer_drag}

	1 (S.L.cp_fahrertuer_dragged)
	(L.L.cp_fahrertuer_pos) (S.L.cp_fahrertuer_lastpos)

	(L.S.mouse_x) 1000 / (L.L.cp_fahrertuer_pos) + (S.L.cp_fahrertuer_pos) s0
	l0 0 <
	{if}
		0 (S.L.cp_fahrertuer_pos)		
	{endif}
	l0 1 >
	{if}
		1 (S.L.cp_fahrertuer_pos)
	{endif}

	(L.L.cp_fahrertuer_pos) (L.L.cp_fahrertuer_lastpos) - (L.S.Timegap) / (S.L.cp_fahrertuer_speed)
{end}

{trigger:cp_Fahrertuer_off}
	0 (S.L.cp_fahrertuer_dragged)
{end}

{trigger:KR_play}
	(L.L.cockpit_KR_play) 0.1 < 
	{if}
		(T.L.ev_kr_play)
	{endif}
	1 (S.L.cockpit_KR_play) (S.L.Snd_Radio)
{end}

{trigger:KR_play_off}
	0.8 (S.L.cockpit_KR_play)
{end}

{trigger:KR_stop}
	1 (S.L.cockpit_KR_stop)
	0 (S.L.cockpit_KR_play) (S.L.Snd_Radio)
	(T.L.ev_kr_stop)
{end}

{trigger:KR_stop_off}
	0 (S.L.cockpit_KR_stop)
{end}

{trigger:taster_standheizung}

	1 (S.L.taster_standheizung_anim)

	(L.L.cp_taster_standheizung_target) ! (S.L.cp_taster_standheizung_target) s1
	1 =
	{if}
		(T.L.ev_VDV_on)
	{else}
		(T.L.ev_VDV_off)
	{endif}

	1 (S.L.cp_taster_standheizung)

	(C.L.auxheat_via_button) !
	{if}
		l1
		1 =
		{if}
			(T.L.ev_VDV_on)
		{else}
			(T.L.ev_VDV_off)
		{endif}
		l0 (S.L.cp_taster_standheizung)
	{endif}
		
{end}

{trigger:taster_standheizung_off}

	0 (S.L.taster_standheizung_anim)
	
	(L.L.cp_taster_standheizung_target)
	{if}
		0 (S.L.cp_taster_standheizung)
	{else}
		0.6 (S.L.cp_taster_standheizung)
	{endif}
{end}

{trigger:cp_wiperlever_drag}

'	Fallunterscheidung: Hebel in x- oder y-Richtung?

	(C.L.wiper_lever)
	{if}
	
		(L.S.mouse_y) abs (L.S.mouse_x) abs >=
		{if}
			(L.S.mouse_y) -50 / (L.L.cockpit_wischerhebel) + 0 max 1 min (S.L.cockpit_wischerhebel) s0
		
'			Stufen:
'			0: Aus
'			1: Intervall
'			2: Langsam
'			3: Schnell

			l0 0.17 <
			{if}
				0 (S.L.cockpit_wischerhebel_mode) (S.L.cp_wischer_intervall_sw) (S.L.cp_wischer_einaus_sw) (S.L.cp_wischer_schnell_sw)
			{else} 
				l0 0.5 <
				{if}
					1 (S.L.cockpit_wischerhebel_mode) (S.L.cp_wischer_intervall_sw)
					0 (S.L.cp_wischer_schnell_sw) (S.L.cp_wischer_einaus_sw)
				{else}
					l0 0.83 <
					{if}
						2 (S.L.cockpit_wischerhebel_mode)
						1 (S.L.cp_wischer_einaus_sw)
						0 (S.L.cp_wischer_intervall_sw) (S.L.cp_wischer_schnell_sw)
					{else}
						3 (S.L.cockpit_wischerhebel_mode)
						1 (S.L.cp_wischer_einaus_sw) (S.L.cp_wischer_schnell_sw)
						0 (S.L.cp_wischer_intervall_sw)
					{endif}
				{endif}
			{endif}
		{else}
			(L.S.mouse_x) -50 / (L.L.cockpit_wischerhebel_x) + 0 max 1 min (S.L.cockpit_wischerhebel_x) s1

'			Waschanlage (Hebel nach oben)	
			l1 0.9 >
			{if}
				(L.L.cp_wischer_wascher_sw) !
				{if}
					(T.L.ev_wischerhebel)
				{endif}
				1 (S.L.cp_wischer_wascher_sw)
			{else}
				(L.L.cp_wischer_wascher_sw)
				{if}
					(T.L.ev_wischerhebel)
				{endif}
				0 (S.L.cp_wischer_wascher_sw)
			{endif}

		{endif}
	{endif}
{end}

{trigger:cp_wiperlever_off}

'	Einrasten auf den festen Positionen:
	(L.L.cockpit_wischerhebel_mode) 3 / (S.L.cockpit_wischerhebel)
	(L.L.cp_wischer_wascher_sw)
	{if}
		(T.L.ev_wischerhebel)
		0 (S.L.cockpit_wischerhebel_x) (S.L.cp_wischer_wascher_sw)
	{endif}
{end}

{trigger:cp_wiper_turnswitch_drag}

'	(C.L.wiper_turnswitch)
'	{if}
	
		(L.S.mouse_y) -50 / (L.L.cockpit_wischer_drehschalter) + 0 max 1 min (S.L.cockpit_wischer_drehschalter) s0
	
'		Stufen:
'		0: Intervall
'		1: Aus
'		2: Langsam
'		3: Schnell

		l0 0.17 <
		{if}
			1 (S.L.cp_wischer_intervall_sw)
			0 (S.L.cockpit_wischer_drehschalter_mode) (S.L.cp_wischer_schnell_sw) (S.L.cp_wischer_einaus_sw)		
		{else} 
			l0 0.5 <
			{if}
				0 (S.L.cp_wischer_intervall_sw) (S.L.cp_wischer_einaus_sw) (S.L.cp_wischer_schnell_sw)
				1 (S.L.cockpit_wischer_drehschalter_mode)
			{else}
				l0 0.83 <
				{if}
					2 (S.L.cockpit_wischer_drehschalter_mode)
					1 (S.L.cp_wischer_einaus_sw)
					0 (S.L.cp_wischer_intervall_sw) (S.L.cp_wischer_schnell_sw)
				{else}
					3 (S.L.cockpit_wischer_drehschalter_mode)
					1 (S.L.cp_wischer_einaus_sw) (S.L.cp_wischer_schnell_sw)
					0 (S.L.cp_wischer_intervall_sw)
				{endif}
			{endif}
		{endif}
'	{endif}
{end}

{trigger:cp_wiper_turnswitch_off}

'	Einrasten auf den festen Positionen:
	(L.L.cockpit_wischer_drehschalter_mode) 3 / (S.L.cockpit_wischer_drehschalter)
{end}

{trigger:cp_microphone}
	1 (S.L.cp_microphone_sw)
	(L.L.debounce) !
	{if}
		(T.L.ev_VDV_on)
		1 (S.L.debounce)
	{endif}
{end}

{trigger:cp_microphone_off}
	0 (S.L.cp_microphone_sw) (S.L.debounce)
{end}

'----------------------
'	Init
'----------------------

{macro:cockpit_init}
	0 (S.L.cockpit_hupe_volume) (S.L.door_handsteuerung)
	1 (S.L.cp_retarder_sw) (S.L.cp_lenkrad_visible) (S.L.cockpit_wischer_drehschalter_mode) (S.L.VDV_Display_Mode)

	(C.L.cockpit_zentralschmierung_dist) random (S.L.cp_zentralschmierung_nextkm)

	0.333 (S.L.cockpit_wischer_drehschalter)
	0 (S.L.VDV_lightswitch_state)
	0 (S.L.cp_klappfenster_1) (S.L.cp_klappfenster_2) (S.L.cp_klappfenster_3) (S.L.cp_klappfenster_4)

	350 (M.V.NrSpecRandom) 5 * 7.5 + (S.L.cp_Fahrgastpendel_traeg)
	351 (M.V.NrSpecRandom) 5 * 7.5 + (S.L.cp_Fahrgastpendel_2_traeg)
	352 (M.V.NrSpecRandom) 0.8 * 0.1 + (S.L.cp_Fahrgastpendel_reib)
	353 (M.V.NrSpecRandom) 0.8 * 0.1 + (S.L.cp_Fahrgastpendel_2_reib)
	354 (M.V.NrSpecRandom) -0.1 * 0.05 - (S.L.cp_Fahrgastpendel_refl)
	355 (M.V.NrSpecRandom) -0.1 * 0.05 - (S.L.cp_Fahrgastpendel_2_refl)
	-1 (S.L.cp_rollo_pos) (S.L.cp_rollo2_pos)	
{end}

'----------------------
'	Frame
'----------------------
{macro:cockpit_frame}

'	Beleuchtung Gangwahltaster

	(L.L.elec_busbar_main) 0 >
	(L.L.elec_failure_general) ! &&
	{if}
		(L.L.antrieb_getr_gangwahl) 2 = (S.L.cockpit_gang1_licht)
		(L.L.antrieb_getr_gangwahl) 3 = (S.L.cockpit_gang2_licht)
		(L.L.antrieb_getr_gangwahl) 4 = (S.L.cockpit_gang3_licht)
		(L.L.antrieb_getr_gangwahl) 5 = (S.L.cockpit_gangD_licht)
		(L.L.antrieb_getr_gangwahl) 1 = (S.L.cockpit_gangN_licht)
		(L.L.antrieb_getr_gangwahl) 0 = (S.L.cockpit_gangR_licht)
	{else}
		0 (S.L.cockpit_gang1_licht) (S.L.cockpit_gang2_licht) (S.L.cockpit_gang3_licht) (S.L.cockpit_gangD_licht) (S.L.cockpit_gangN_licht) (S.L.cockpit_gangR_licht)
	{endif}

'Übertragen der Schalterstellungen:
	(L.L.cp_retarder_sw) (S.L.antrieb_retarder_sw)
	(L.L.cp_retarder_sw_direkt) (S.L.antrieb_retarder_sw_direkt)
	(L.L.cp_wischer_schnell_sw) (S.L.wiper_schnell_sw)
	(L.L.cp_wischer_einaus_sw) (S.L.wiper_einaus_sw)
	(L.L.cp_wischer_intervall_sw) (S.L.wiper_intervall_sw)
	(L.L.cp_wischer_wascher_sw) (S.L.wiper_wascher_sw)

	(M.L.tacho_frame)
	(M.L.uhr_frame)
	(M.L.drehzahlmesser_frame)
	(M.L.hupe_frame)
	(M.L.blinkerhebel_frame)
	(M.L.wischerhebel_frame)
	(M.L.wischer_drehschalter_frame)
	(M.L.oeldruck_frame)
	(M.L.tankuhr_frame)
	(M.L.cockpitlights_frame)
	(M.L.schluessel_frame)
	(M.L.odometer_frame)
	(M.L.fahrertuer_frame) 
	(M.L.rollo_frame)
	(M.L.engine_thermometer_frame)
	(M.L.microphone_frame)
	(M.L.pressure_warning_needle_frame)
	(M.L.zentralschmierung_frame)
	(M.L.Thermometer_frame)
	(M.L.Fahrgastpendel)
	(M.L.schlaufen)
	(M.L.klimator_frame)
	
'	Abfrage, wenn bei Motor aus Feststellbremse gelöst ist, dann piepen
	(L.L.bremse_feststell) !
	(L.L.engine_on) ! &&
	{if}
		1 (S.L.brake_warning)
	{else}
		0 (S.L.brake_warning)
	{endif}
{end}

{macro:uhr_frame}
	(L.L.elec_busbar_avail) 0.5 >
	{if}
		(L.S.Time) s0 60 / (S.L.cockpit_uhr_min) 12 / (S.L.cockpit_uhr_std)
		l0 trunc (S.L.cockpit_uhr_sek)
	{endif}
{end} 

{macro:drehzahlmesser_frame}
	(L.L.engine_n) 3000 270 / / (S.L.cockpit_drehzahlwinkel)
{end}

{macro:hupe_frame}
	(L.L.elec_busbar_main) (C.L.elec_busbar_minV) >
	{if}
		(L.L.cockpit_hupe) 1 =
		{if}
			(L.L.cockpit_hupe_volume) 1 <
			{if}
				(L.L.cockpit_hupe_volume) (L.S.Timegap) 10 * + (S.L.cockpit_hupe_volume)
			{else}
				1 (S.L.cockpit_hupe_volume)
			{endif}
		{else}
			(L.L.cockpit_hupe_volume) 0 >
			{if}
				(L.L.cockpit_hupe_volume) (L.S.Timegap) 10 * - (S.L.cockpit_hupe_volume)
			{else}
				0 (S.L.cockpit_hupe_volume)
			{endif}
		{endif}
	{else}
		(L.L.cockpit_hupe_volume) 0 >
		{if}
			(L.L.cockpit_hupe_volume) (L.S.Timegap) 10 * - (S.L.cockpit_hupe_volume)
		{else}
			0 (S.L.cockpit_hupe_volume)
		{endif}
	{endif}	
	
{end}

{macro:blinkerhebel_frame}
	(L.L.lights_sw_blinker) 1 =
	{if}	
		-1 (S.L.cockpit_blinkerhebel)
	{else}
		(L.L.lights_sw_blinker) 2 =
		{if}
			1 (S.L.cockpit_blinkerhebel)
		{else}
			0 (S.L.cockpit_blinkerhebel)
		{endif}
	{endif}

'	Hebel-Animation für Fernlicht
	(L.L.lights_sw_fern)
	{if}	
		(L.L.cockpit_fernlichthebel) -1 = !
		{if}
			1 (S.L.cockpit_fernlichthebel)
		{endif}

		(L.L.cp_schluessel_rot) 0.8 >
		{if}
			-1 (S.L.cockpit_fernlichthebel)
		{endif}
	{else}
		0 (S.L.cockpit_fernlichthebel)
	{endif}
{end}

{macro:wischerhebel_frame}

	(L.L.cockpit_wischerhebel_lastmode) (L.L.cockpit_wischerhebel_mode) = !
	{if}
		(T.L.ev_wischerhebel)
	{endif}
	(L.L.cockpit_wischerhebel_mode) (S.L.cockpit_wischerhebel_lastmode)
{end}

{macro:wischer_drehschalter_frame}

	(L.L.cockpit_wischer_drehschalter_lastmode) (L.L.cockpit_wischer_drehschalter_mode) = !
	{if}
		(T.L.ev_wischerhebel)
	{endif}
	(L.L.cockpit_wischer_drehschalter_mode) (S.L.cockpit_wischer_drehschalter_lastmode)
{end}

{macro:cockpitlights_frame}

'	Startup-Timer
	(L.L.vdv_on)
	{if}
		(L.L.startup) (L.S.Timegap) + 10 min (S.L.startup)

'	Störungsmelder
	(L.L.bremse_p_tank01) 550000 <
	(L.L.bremse_p_tank02) 550000 < ||
	(L.L.engine_knickschutz_eingriff) ||
	(S.L.cockpit_light_masterfailure)
	(S.L.cockpit_light_caution)


	{else}
		0 (S.L.startup) (S.L.cockpit_light_masterfailure) (S.L.cockpit_light_caution)
	{endif}

'	Blinker
	(L.L.lights_blinkgeber) (S.L.cockpit_light_blinker)

'	Fernlicht
	(L.L.lights_fern) (S.L.cockpit_light_fernlicht)

'	Haltewunsch
	(L.L.haltewunsch) (L.L.haltewunsch_01) (L.L.haltewunsch_45) (L.L.haltewunsch_23) || || || (S.L.cockpit_light_haltewunsch)

'	Batterie
	(L.L.elec_ladekontrolle) (L.L.elec_busbar_main) * (L.L.vdv_on) *
	(S.L.cockpit_light_batterie)

'	Nebelscheinwerfer
	(L.L.lights_nebelschw) (L.L.elec_busbar_main) *
	(S.L.cockpit_light_nebelschw)

'	Kontrolle Feststellbremse
	(L.L.bremse_p_Brzyl_FBA) 650000 <
	(L.L.elec_busbar_main) *
	(S.L.cockpit_light_feststellbremse)

'	Geschwindigkeitswarnung
	(L.L.Velocity) 54 > (L.L.elec_busbar_main) *
	(S.L.cockpit_light_speedwarning)
	
'	Kinderwagenwunsch
	(L.L.door_kinderwagenwunsch) (L.L.elec_busbar_main) *
	(S.L.cockpit_light_kinderwagenwunsch)

'	Kippschalter-Beleuchtung
	(L.L.cp_retarder_sw_direkt) (L.L.elec_busbar_main) *
	(S.L.cockpit_light_retarder_direkt)

	(L.L.cp_retarder_sw) (L.L.elec_busbar_main) *
	(S.L.cockpit_light_retarder)

	(L.L.cp_fahrerlicht_sw) (L.L.elec_busbar_main) *
	(S.L.cockpit_light_fahrerlicht)

	(L.L.cp_licht_untenrechts_sw) (L.L.elec_busbar_main) *
	(S.L.cockpit_light_licht_untenrechts)

	(L.L.cp_licht_unterdeck_sw) (L.L.elec_busbar_main) *
	(S.L.cockpit_light_licht_unterdeck)

'	(L.L.cp_licht_oberdeck_sw) (L.L.elec_busbar_main) *
'	(S.L.cockpit_light_licht_oberdeck)

	(L.L.cp_wischer_schnell_sw) (L.L.elec_busbar_main) *
	(S.L.cockpit_light_wischer_schnell)

	(L.L.cp_wischer_einaus_sw) (L.L.elec_busbar_main) *
	(S.L.cockpit_light_wischer_einaus)

	(L.L.cp_wischer_intervall_sw) (L.L.elec_busbar_main) *
	(S.L.cockpit_light_wischer_intervall)
	
	(L.L.cp_wischer_wascher_sw) (L.L.elec_busbar_main) *
	(S.L.cockpit_light_wischer_wascher)

	(L.L.cp_heizluefter_sw) (L.L.elec_busbar_main) *
	(S.L.cockpit_light_heizluefter)
	
	(L.L.cp_spiegelheizung_sw) (L.L.elec_busbar_main) *
	(S.L.cockpit_light_spiegelheizung)

	(L.L.cp_motorkuehlung_sw) (L.L.elec_busbar_main) *
	(S.L.cockpit_light_motorkuehlung)

	(L.L.door_handsteuerung) (L.L.elec_busbar_main) *
	(S.L.cockpit_light_tuer_handsteuerung)

	(L.L.cp_ASR_off) (L.L.elec_busbar_main) *
	(S.L.cockpit_light_ASR_off)

	(L.L.cp_hub_up_sw) (L.L.elec_busbar_main) *
	(S.L.cockpit_light_hub_up)

	(L.L.cp_hub_dn_sw) (L.L.elec_busbar_main) *
	(S.L.cockpit_light_hub_dn)

	(L.L.cp_knick_ovrd_sw) (L.L.elec_busbar_main) *
	(S.L.cockpit_light_knick_ovrd)

	(L.L.cp_kneeling_sw) (L.L.elec_busbar_main) *
	(S.L.cockpit_light_kneeling_sw)

'	Dummy-Schalter:

	(L.L.cp_dummy_sw01) (L.L.elec_busbar_main) *
	(S.L.cp_dummy_func01)

	(L.L.cp_dummy_sw02) (L.L.elec_busbar_main) *
	(S.L.cp_dummy_func02)

	(L.L.cp_dummy_sw03) (L.L.elec_busbar_main) *
	(S.L.cp_dummy_func03)

	(L.L.cp_dummy_sw04) (L.L.elec_busbar_main) *
	(S.L.cp_dummy_func04)

	(L.L.cp_dummy_sw05) (L.L.elec_busbar_main) *
	(S.L.cp_dummy_func05)

	(L.L.cp_dummy_sw06) (L.L.elec_busbar_main) *
	(S.L.cp_dummy_func06)

	(L.L.cp_dummy_sw07) (L.L.elec_busbar_main) *
	(S.L.cp_dummy_func07)

	(L.L.cp_dummy_sw08) (L.L.elec_busbar_main) *
	(S.L.cp_dummy_func08)

	(L.L.cp_dummy_sw09) (L.L.elec_busbar_main) *
	(S.L.cp_dummy_func09)

	(L.L.cp_dummy_sw10) (L.L.elec_busbar_main) *
	(S.L.cp_dummy_func10)


'	Meldelampen für Kneeling und ECAS
	
'	Selftest: Beim Einschalten der Elektrik leuchten Melde- und Störlampe kurz auf, daher zwei Timer laufen lassen:
	(L.L.elec_busbar_main) (C.L.elec_busbar_minV) >
	{if}
		(L.L.cockpit_light_kneeling_timer) (L.S.Timegap) + (S.L.cockpit_light_kneeling_timer)
		(L.L.cockpit_light_kneeling_failure_timer) (L.S.Timegap) + (S.L.cockpit_light_kneeling_failure_timer)	
	{else}
		0 (S.L.cockpit_light_kneeling_failure_timer) (S.L.cockpit_light_kneeling_timer)		
	{endif}

'	Bedingungen fürs Leuchten:
	(L.L.elec_busbar_main) (C.L.elec_busbar_minV) >
	(L.L.cockpit_light_kneeling_failure_timer) (C.L.cockpit_light_kneeling_failure_selftesttime) < &&
	(S.L.cockpit_light_kneeling_failure)

	(L.L.elec_busbar_main) (C.L.elec_busbar_minV) >
	(L.L.cockpit_light_kneeling_timer) (C.L.cockpit_light_kneeling_selftesttime) <
	(L.L.bremse_kneeling) ||
	(L.L.bremse_p_Tank04) 750000 < (L.S.GetTime) 1 % 0.5 < && || &&
	(S.L.cockpit_light_kneeling)

	(L.L.startup) 0 >
	(L.L.startup) 3 < &&
	{if}
		1 (S.L.cockpit_light_caution) (S.L.cockpit_light_masterfailure) (S.L.cockpit_light_blinker) (S.L.cockpit_light_fernlicht) (S.L.cockpit_light_feststellbremse) (S.L.lm_ABSASR) (S.L.cockpit_light_haltewunsch) (S.L.cockpit_light_nebelschw) (S.L.cockpit_light_batterie) (S.L.cockpit_light_kinderwagenwunsch)
	{endif}

	(L.L.startup) 3 >
	(L.L.startup) 5 < &&
	{if}
		0 (S.L.cockpit_light_caution) (S.L.cockpit_light_masterfailure) (S.L.cockpit_light_blinker) (S.L.cockpit_light_fernlicht) (S.L.cockpit_light_feststellbremse) (S.L.lm_ABSASR) (S.L.cockpit_light_haltewunsch) (S.L.cockpit_light_nebelschw) (S.L.cockpit_light_batterie) (S.L.cockpit_light_kinderwagenwunsch)
	{endif}
{end}

{macro:tankuhr_frame}
	(L.L.engine_tank_content) (L.L.elec_busbar_main) * s0

	(L.L.cockpit_tankuhr) s1
	5 s2
	5 s3
	(M.L.traegheit)	
	l1 (S.L.cockpit_tankuhr)
{end}

{macro:engine_thermometer_frame}
	(L.L.engine_temperature) (F.L.cockpit_engine_temperature) (L.L.elec_busbar_main) * s0

	(L.L.cockpit_motortemperaturwinkel) s1
	5 s2
	5 s3
	(M.L.traegheit)	
	l1 (S.L.cockpit_motortemperaturwinkel)
{end}

{macro:klappfenstersound_1}
	l1
	{if}
		(T.L.ev_klappfenster1_opn)
	{else}
		(T.L.ev_klappfenster1_cls)
	{endif}	
{end}

{macro:klappfenstersound_2}
	l1
	{if}
		(T.L.ev_klappfenster2_opn)
	{else}
		(T.L.ev_klappfenster2_cls)
	{endif}	
{end}

{macro:klappfenstersound_T1}
	l1
	{if}
		(T.L.ev_klappfenster_opn_T1)
	{else}
		(T.L.ev_klappfenster_cls_T1)
	{endif}	
{end}

{macro:klappfenstersound_T2}
	l1
	{if}
		(T.L.ev_klappfenster_opn_T2)
	{else}
		(T.L.ev_klappfenster_cls_T2)
	{endif}	
{end}

{macro:schluessel_frame}

	(L.L.cp_schluessel_trans_lastmode) (L.L.cp_schluessel_trans_mode) = !
	{if}
		(T.L.ev_schluessel_steck)
	{endif}
	(L.L.cp_schluessel_trans_mode) (S.L.cp_schluessel_trans_lastmode)


	(L.L.cp_schluessel_rot_lastmode) (L.L.cp_schluessel_rot_mode) = !
	{if}
		(T.L.ev_schluessel_dreh)
	{endif}
	(L.L.cp_schluessel_rot_mode) (S.L.cp_schluessel_rot_lastmode)
{end}

{macro:traegheit}

'Simuliert träges Verhalten (exponentiell)

'Ladekonventionen:
'	Sollwert		l0
'	Istwert			l1
'	Konstante Anlauf	l2 (Einheiten/s)
'	Konstante Ablauf	l3 (Einheiten/s)

'Anlauf oder Auslauf?
	l0 l1 > 
	{if}
		l2 (L.S.Timegap) * 1 min -1 max s4
	{else}
		l3 (L.S.Timegap) * 1 min -1 max s4
	{endif}


'Sollwert:
	l0
'Istwert:
	l1
'Beschleunigung:
	- l4 *
'Addition zum Istwert:
	l1 + s1
{end}


{macro:odometer_frame}
	(L.L.kmcounter_km) (L.L.kmcounter_m) 1000 / + 10 *
	(S.L.cp_odometer_01)

	(L.L.cp_odometer_01) 10 / trunc 
	(L.L.cp_odometer_01) 10 / d trunc - (F.L.odometer_10er-uebertrag) +
	(S.L.cp_odometer_1)

	(L.L.cp_odometer_1) 10 / trunc 
	(L.L.cp_odometer_1) 10 / d trunc - (F.L.odometer_10er-uebertrag) +
	(S.L.cp_odometer_10)

	(L.L.cp_odometer_10) 10 / trunc 
	(L.L.cp_odometer_10) 10 / d trunc - (F.L.odometer_10er-uebertrag) +
	(S.L.cp_odometer_100)

	(L.L.cp_odometer_100) 10 / trunc 
	(L.L.cp_odometer_100) 10 / d trunc - (F.L.odometer_10er-uebertrag) +
	(S.L.cp_odometer_1000)

	(L.L.cp_odometer_1000) 10 / trunc 
	(L.L.cp_odometer_1000) 10 / d trunc - (F.L.odometer_10er-uebertrag) +
	(S.L.cp_odometer_10000)

	(L.L.cp_odometer_10000) 10 / trunc 
	(L.L.cp_odometer_10000) 10 / d trunc - (F.L.odometer_10er-uebertrag) +
	(S.L.cp_odometer_100000)


	(L.L.kmcounter_m) 100 / (S.L.cp_odometer_01)
{end}


{macro:fahrertuer_frame}

	(L.L.cp_fahrertuer_dragged) !
	{if}
		(L.L.cp_fahrertuer_pos) (L.S.Timegap) (L.L.cp_fahrertuer_speed) * + (S.L.cp_fahrertuer_pos)

		(L.L.cp_fahrertuer_pos) 1 >
		{if}
			1 (S.L.cp_fahrertuer_pos)
			(L.L.cp_fahrertuer_speed) /-/ 0.7 * (S.L.cp_fahrertuer_speed)
		{endif}
		(L.L.cp_fahrertuer_pos) 0 <
		{if}
			0 (S.L.cp_fahrertuer_speed) (S.L.cp_fahrertuer_pos)
		{endif}

		(L.L.cp_fahrertuer_pos) 0 >
		{if}
			(L.L.cp_fahrertuer_speed) (L.S.Timegap) (L.L.A_Trans_Y) -1 * (C.L.cp_fahrertuer_anschlagseite) * (L.L.A_Trans_X) -1 * + 0.3 * (L.L.cp_fahrertuer_globalangle) * * + (S.L.cp_fahrertuer_speed)
		{endif}
	
		(L.L.cp_fahrertuer_speed) s0 (S.L.cp_fahrertuer_lastspeed)
		l0 0 >
		{if}
			l0 (L.S.Timegap) 2 * - (S.L.cp_fahrertuer_speed)
		{endif}
		l0 0 <
		{if}
			l0 (L.S.Timegap) 2 * + (S.L.cp_fahrertuer_speed)
		{endif}


		(L.L.cp_fahrertuer_speed) 0 > (L.L.cp_fahrertuer_lastspeed) 0 < &&
		(L.L.cp_fahrertuer_speed) 0 < (L.L.cp_fahrertuer_lastspeed) 0 > && ||
		{if}
			0 (S.L.cp_fahrertuer_speed)
		{endif}	 
	
	{endif}

	(L.L.cp_fahrertuer_pos) 0 > (L.L.cp_fahrertuer_open) ! &&
	{if}
		(T.L.ev_fahrertuer_auf)
		1 (S.L.cp_fahrertuer_open)
	{endif}

	(L.L.cp_fahrertuer_pos) 0 = (L.L.cp_fahrertuer_open) &&
	{if}
		(T.L.ev_fahrertuer_zu)
		0 (S.L.cp_fahrertuer_open)
	{endif}

	(L.L.cp_fahrertuer_pos) 140 * 27 + 3.14 * 180 / sin (S.L.cp_fahrertuer_globalangle) 

	(L.L.velocity) (L.L.cp_velocity_last) - (S.L.cp_acceleration)
	(L.L.velocity) (S.L.cp_velocity_last)
	

{end}

{macro:rollo_frame}

{end}



{macro:microphone_frame}

	(L.L.Clutch) 0.2 > (L.L.cp_microphone_sw) ||
	(L.L.elec_busbar_main) (C.L.elec_busbar_minV) > && s0
	(L.L.Snd_Microphone) s1


	l0 l1 ! &&
	{if}
		(T.L.micro_lautsprecherknack_start)
	{endif}

	l0 ! l1 &&
	{if}
		(T.L.micro_lautsprecherknack_end)
	{endif}


	l0 (S.L.Snd_Microphone)
{end}


{macro:pressure_warning_needle_frame}

	(L.L.bremse_p_Tank01) (L.L.bremse_p_Tank02) + 2 / (S.L.cockpit_warndruck) (F.L.cockpit_warndruck) (S.L.cockpit_warndruckwinkel)

{end}

{macro:zentralschmierung_frame}

	(L.L.cp_zentralschmierung_nextkm) (L.L.velocity) 3600 / (L.S.Timegap) * + (S.L.cp_zentralschmierung_nextkm)
	(C.L.cockpit_zentralschmierung_dist) >
	(L.L.cp_zentralschmierung_runtime) (C.L.cockpit_zentralschmierung_maxtime) < &&
	{if}
		1 (S.L.cockpit_light_zentralschmierung)
		(L.L.cp_zentralschmierung_runtime) (L.S.Timegap) + (S.L.cp_zentralschmierung_runtime)
	{else}
		(L.L.cockpit_light_zentralschmierung)
		{if}
			0 (S.L.cp_zentralschmierung_nextkm)
		{endif}
		0 (S.L.cockpit_light_zentralschmierung) (S.L.cp_zentralschmierung_runtime)
	{endif}	

{end}

{macro:Thermometer_frame}

	(L.L.Cabinair_Temp) s0 trunc " 3" $IntToStrEnh "." $+ 
	l0 abs l0 abs trunc - 10 * trunc " 1" $IntToStrEnh $+ "C" $+
	(S.$.cockpit_temperatur)
{end}

{trigger:cp_Fahrgastpendel}
	1 (S.L.cp_Fahrgastpendel_drag)
{end}

{trigger:cp_Fahrgastpendel_2}
	1 (S.L.cp_Fahrgastpendel_2_drag)
{end}

{trigger:cp_Fahrgastpendel_off}
	0 (S.L.cp_Fahrgastpendel_drag)
{end}

{trigger:cp_Fahrgastpendel_2_off}
	0 (S.L.cp_Fahrgastpendel_2_drag)
{end}

{trigger:cp_Fahrgastpendel_drag}
	(L.L.cp_Fahrgastpendel_drag)
	{if}
		(L.L.cp_Fahrgastpendel_Pos) (L.S.mouse_y) 500 / + 1 min 0 max s0
		l0 (L.L.cp_Fahrgastpendel_Pos) - (L.S.Timegap) / (S.L.cp_Fahrgastpendel_Speed)
		l0 (S.L.cp_Fahrgastpendel_Pos)
	{endif}
{end}

{trigger:cp_Fahrgastpendel_2_drag}
	(L.L.cp_Fahrgastpendel_2_drag)
	{if}
		(L.L.cp_Fahrgastpendel_2_Pos) (L.S.mouse_y) 500 / + 1 min 0 max s0
		l0 (L.L.cp_Fahrgastpendel_2_Pos) - (L.S.Timegap) / (S.L.cp_Fahrgastpendel_2_Speed)
		l0 (S.L.cp_Fahrgastpendel_2_Pos)
	{endif}
{end}

{macro:Fahrgastpendel}
'Sollwert: (wenn mindestens ein Typ an der Stelle durchgeht)
	7 (M.V.GetHumanCountOnPathLink) 1 min s4

'Wenn ein Fahrgast durchwill, dann überschreibe die "Drag"-Eigenschaft:
	l4 {if} 0 (S.L.cp_Fahrgastpendel_drag) (S.L.cp_Fahrgastpendel_2_drag) {endif}

'1:====================================

'Differenz * InvTrägheit = Beschleunigung
	l4 (L.L.cp_Fahrgastpendel_Pos) - (L.L.cp_Fahrgastpendel_traeg) * s1

	(L.L.cp_Fahrgastpendel_drag) !
	{if}

'Anwendung einer Reibungskraft:
		l1 (L.L.cp_Fahrgastpendel_Speed) sgn (L.L.cp_Fahrgastpendel_reib) * - s0
'Prüfen, ob sich die Beschleunigung infolge der Reibung umkehrt - dann wird sie auf 0 gesetzt:
		l0 l1 * 0 < {if} 0 s0 {endif}
'Anwenden der Beschleunigung:
		(L.L.cp_Fahrgastpendel_Speed) l0 (L.S.Timegap) * + (S.L.cp_Fahrgastpendel_Speed)
'Anwenden der Position:
		(L.L.cp_Fahrgastpendel_Pos) (L.L.cp_Fahrgastpendel_Speed) (L.S.Timegap) * + (S.L.cp_Fahrgastpendel_Pos) s0
	{else}
		(L.L.cp_Fahrgastpendel_Pos) s0
	{endif}


'Limits: (Anschlag an Haltestange mit 10% Abprallstärke)
	l0 0 <
	{if}
		0 (S.L.cp_Fahrgastpendel_Pos)
		(T.L.ev_fahrgastpendel_zu)
		(L.L.cp_Fahrgastpendel_Speed) (L.L.cp_Fahrgastpendel_refl) * (S.L.cp_Fahrgastpendel_Speed)
	{endif}
'(anderes Ende ohne Reflexion)
	l0 1 >
	{if}
		1 (S.L.cp_Fahrgastpendel_Pos)
		0 (S.L.cp_Fahrgastpendel_Speed)
	{endif}

'2:====================================

'Differenz * InvTrägheit = Beschleunigung
	l4 (L.L.cp_Fahrgastpendel_2_Pos) - (L.L.cp_Fahrgastpendel_2_traeg) * s1

	(L.L.cp_Fahrgastpendel_2_drag) !
	{if}

'Anwendung einer Reibungskraft:
		l1 (L.L.cp_Fahrgastpendel_2_Speed) sgn (L.L.cp_Fahrgastpendel_2_reib) * - s0
'Prüfen, ob sich die Beschleunigung infolge der Reibung umkehrt - dann wird sie auf 0 gesetzt:
		l0 l1 * 0 < {if} 0 s0 {endif}
'Anwenden der Beschleunigung:
		(L.L.cp_Fahrgastpendel_2_Speed) l0 (L.S.Timegap) * + (S.L.cp_Fahrgastpendel_2_Speed)
'Anwenden der Position:
		(L.L.cp_Fahrgastpendel_2_Pos) (L.L.cp_Fahrgastpendel_2_Speed) (L.S.Timegap) * + (S.L.cp_Fahrgastpendel_2_Pos) s0
	{else}
		(L.L.cp_Fahrgastpendel_2_Pos) s0
	{endif}


'Limits: (Anschlag an Haltestange mit 10% Abprallstärke)
	l0 0 <
	{if}
		0 (S.L.cp_Fahrgastpendel_2_Pos)
		(T.L.ev_fahrgastpendel_2_zu)
		(L.L.cp_Fahrgastpendel_2_Speed) (L.L.cp_Fahrgastpendel_2_refl) * (S.L.cp_Fahrgastpendel_2_Speed)
	{endif}
'(anderes Ende ohne Reflexion)
	l0 1 >
	{if}
		1 (S.L.cp_Fahrgastpendel_2_Pos)
		0 (S.L.cp_Fahrgastpendel_2_Speed)
	{endif}

{end}

'Schlaufenpendeln für Handschlaufen - dreist abgeschrieben, danke dafür! ;)
{macro:schlaufen}
	(L.L.A_Trans_X) 9.81 / (C.L.schlaufen_min) min (C.L.schlaufen_max) max (L.L.schlaufen_anim) - (C.L.schlaufen_faktor) * (L.S.Timegap) / (L.S.Timegap) (C.L.schlaufen_speed) * /-/ exp (L.L.schlaufen_anim_speed) * + (S.L.schlaufen_anim_speed) (L.S.Timegap) * (L.L.schlaufen_anim) + 
	(S.L.schlaufen_anim) 
{end}

{macro:klimator_frame}
	(L.L.cp_klimator_sw) (L.L.elec_busbar_main) * s1
	l1 100 * (L.L.cp_klimator_RPM) > 
	{if}
		1.5 s0
	{else}
		0.5 s0
	{endif}
	l1 100 * (L.L.cp_klimator_RPM) - s0 * (L.S.Timegap) * (L.L.cp_klimator_RPM) + (S.L.cp_klimator_RPM)
	(L.L.cp_klimator_sw) 0.5 >
	{if}
		(L.L.elec_busbar_Rinv_summe) (C.L.cp_klimator_Rinv) + (S.L.elec_busbar_Rinv_summe)
	{else}
		(L.L.cp_klimator_sw) -0.5 <
		{if}
			(L.L.elec_busbar_Rinv_summe) (C.L.cp_klimator_Rinv) 0.6 * + (S.L.elec_busbar_Rinv_summe)
		{endif}
	{endif}
	(L.L.engine_n) 399 >
	{if}
		(L.L.cp_heizluefter_sw) (L.L.elec_busbar_main) * s1
	{else}
		0 s1
	{endif}
	l1 100 * (L.L.cp_cabinheater_RPM) > 
	{if}
		6 s0
	{else}
		1.0 s0
	{endif}
	l1 100 * (L.L.cp_cabinheater_RPM) - s0 * (L.S.Timegap) * (L.L.cp_cabinheater_RPM) + (S.L.cp_cabinheater_RPM)
	(L.L.cp_heizluefter_sw) 0.5 >
	{if}
		(L.L.elec_busbar_Rinv_summe) (C.L.cp_cabinheater_Rinv) + (S.L.elec_busbar_Rinv_summe)
	{else}
		(L.L.cp_heizluefter_sw) -0.5 <
		{if}
			(L.L.elec_busbar_Rinv_summe) (C.L.cp_cabinheater_Rinv) 0.6 * + (S.L.elec_busbar_Rinv_summe)
		{endif}
	{endif}
{end}