{trigger:RBL_power}
(L.L.RBL_power) ! (S.L.RBL_power)
{end}

{trigger:RBL_Menue}
1 (S.L.RBL_Menue)
{end}

{trigger:RBL_1}
1 (S.L.RBL_Taste)
{end}

{trigger:RBL_2}
2 (S.L.RBL_Taste)
{end}

{trigger:RBL_3}
3 (S.L.RBL_Taste)
{end}

{trigger:RBL_4}
4 (S.L.RBL_Taste)
{end}

{trigger:RBL_5}
5 (S.L.RBL_Taste)
{end}

{trigger:RBL_6}
6 (S.L.RBL_Taste)
{end}

{trigger:RBL_7}
7 (S.L.RBL_Taste)
{end}

{trigger:RBL_8}
8 (S.L.RBL_Taste)
{end}

{trigger:RBL_9}
9 (S.L.RBL_Taste)
{end}

{trigger:RBL_0}
0 (S.L.RBL_Taste)
{end}

{trigger:RBL_OK}
10 (S.L.RBL_Taste)
{end}

{trigger:RBL_Rueck}
11 (S.L.RBL_Taste)
{end}

{macro:RBL_Frame}
	(L.L.RBL_power)
	{if}
		(L.L.RBL_BootMode) 5 < {if} (L.S.timegap) (L.L.RBL_timer) + (S.L.RBL_timer) {endif}

		(L.L.RBL_timer) trunc 2 =
		(L.L.RBL_BootMode) 6 < &&
		{if}
			0 (S.L.RBL_timer)
			(L.L.RBL_BootMode) 1 + (S.L.RBL_BootMode)
		{endif}
			
		(L.L.RBL_BootMode) 5 <
		{if}
			"Tablet-Display\Boot" (L.L.RBL_BootMode) $IntToStr $+ ".bmp" $+ (S.$.RBL_Displaytausch)
		{endif}
		
		(L.L.RBL_BootMode) 5 =
		{if}
'==========================================================================================================================	
			(L.L.RBL_Menue) 1 =
			{if}
				(L.L.Fehler_Flag)
				{if}
					"Tablet-Display\Kurseingabe_Fehler.bmp" (S.$.RBL_Displaytausch)	
					1 (S.L.OK_Meld)
					0 (S.L.RBL_Tastenfeld)
					2 (S.L.Kursnr_eing)
				{else}
					"Tablet-Display\Kurseingabe.bmp" (S.$.RBL_Displaytausch)				
					1 (S.L.RBL_Tastenfeld)
					1 (S.L.Kursnr_eing)
			
					(L.L.RBL_Taste) 10 < (L.$.RBL_Kursnr) $length 5 <  &&
					{if}
						(L.$.RBL_Kursnr) (L.L.RBL_Taste) $IntToStr $+ (S.$.RBL_Kursnr)
					{endif}			
					(L.L.RBL_Taste) 11 =
					{if}
						(L.$.RBL_Kursnr) "" $= !
						{if}
							(L.$.RBL_Kursnr) $length 1 - $SetLengthL (S.$.RBL_Kursnr)
						{else}
							0 (S.L.RBL_Menue)
						{endif}
					{endif}		
				{endif}
				
				(L.L.RBL_Taste) 10 =
				{if}
					(L.$.RBL_Kursnr) $length 5 <
'					(L.S.schedule_active) ! ||
					{if}
						(L.L.Fehler_Flag) !
						{if}
						1	
						{else}
						0
						{endif}
						(S.L.Fehler_Flag)
					{else}
						0 (S.L.RBL_Menue)	
					{endif}
				{endif}
			{endif}
'==========================================================================================================================			
'==========================================================================================================================			
			(L.L.RBL_Menue) 0 =
			{if}
				0 (S.L.Kursnr_eing)
				0 (S.L.RBL_Tastenfeld)				
				"Tablet-Display\Hauptbildschirm.bmp" (S.$.RBL_Displaytausch)
'				"80501" (S.$.RBL_Kursnr)

			(L.$.RBL_Kursnr) $length 0 >
			{if}
				(M.V.GetTTBusstopIndex) s2
				(M.V.GetTTBusstopCount) s3

				l2 2 + l3 >
				{if}
				""
				{else}
				l2 2 + (M.V.GetTTBusstopName)
				{endif}
				"@" $+

				l2 1 + l3 >
				{if}
				"" $+
				{else}
				l2 1 + (M.V.GetTTBusstopName) $+
				{endif}
				"@" $+

				l2 (M.V.GetTTBusstopName) $+ "@" $+

				l2 1 - -1 =
				{if}
				"" $+
				{else}
				 l2 1 - (M.V.GetTTBusstopName) $+
				{endif}	
				(S.$.RBL_Haltestellen)

'				"Meidling S@Eichenstraße@Dörfelstraße@Längenfeldgasse" (S.$.RBL_Haltestellen)
				
'		Versätungs-Anzeige				
				(M.V.GetTTDelay) 60 / abs trunc 60 % s0
				(M.V.GetTTDelay) 60 % abs trunc s1
				(M.V.GetTTDelay) 0 > {if} "+" {else} "-" {endif}
				l0 "02" $IntToStrEnh $+ ":" $+ l1 "02" $IntToStrEnh $+
				(S.$.RBL_Versp)
			{else}
				"" (S.$.RBL_Versp) (S.$.RBL_Haltestellen)
			{endif}			
'		Datum:
				(L.S.Day) "02" $IntToStrEnh "." $+ (L.S.Month) "02" $IntToStrEnh $+ "." $+ (L.S.Year) "04" $IntToStrEnh $+
				"  " $+
'		Uhrzeit-Berechnung:
				(L.S.Time) 3600 / trunc "02" $IntToStrEnh $+ ":" $+
				(L.S.Time) 60 / trunc 60 % "02" $IntToStrEnh $+ ":" $+
				(L.S.Time) 60 % "02" $IntToStrEnh $+
				(S.$.RBL_DatumUhrzeit)
			{endif}
'==========================================================================================================================			
		{endif}
	{else}
		 "Tablet-Display\Screen_leer.bmp" (S.$.RBL_Displaytausch)
		 "" (S.$.RBL_Kursnr) (S.$.RBL_Haltestellen) (S.$.RBL_Versp) (S.$.RBL_DatumUhrzeit)
		 0 (S.L.RBL_BootMode) (S.L.RBL_timer)
	{endif}
	100 (S.L.RBL_Taste)
{end}